next | previous | forward | backward | up | top | index | toc | Macaulay2 website
ReflexivePolytopesDB :: Kreuzer-Skarke description headers

Kreuzer-Skarke description headers -- information contained in the description line

Each 4D reflexive polytope in the Kreuzer-Skarke database contains summary information about the polytope. Here, we explain this information. A 3D polytope description line is similar, but somehwat simpler.

We will do this on an example, and see how to obtain this information directly.

i1 : topes = kreuzerSkarke(5,Limit=>1);
using offline data file: ks5-n50.txt
i2 : A = matrix topes_0

o2 = | 1 0 0 0 1 0 0  2  -2 -1 |
     | 0 1 0 0 0 1 -2 -1 2  0  |
     | 0 0 1 0 0 1 -1 -2 0  2  |
     | 0 0 0 1 1 0 2  0  -1 -2 |

              4        10
o2 : Matrix ZZ  <--- ZZ
i3 : header = description topes_0

o3 = 4 10  M:25 10 N:10 9 H:5,20 [-30] id:0

This header line is what we wish to explain now.

The quick description:

  • '4 10': the first 2 numbers are the number of rows and columns of the matrix $A$
  • 'M:25 10': number of lattice points and the number of vertices of the 4-dimensional lattice polytope $P$ which is the convex hull of the columns of the matrix $A$
  • 'N: 10 9' is the number of lattice points and the number of vertices of the polar dual polytope $P^o$ of $P$
  • 'H: 5,20 [-30]' are the Hodge numbers $h^{1,1}(X)$, $h^{1,2}(X)$, and the topological Euler characteristic of $X$, where $X$ is the Calabi-Yau variety described next
  • 'id: 0' is added by { t kreuzerSkarke}: each retrieved entry gets an id, starting with 0

Here, $X$ is defined as follows. Consider the Fano toric variety corresponding to the polytope $P$ (or, equivalently) to the fan determined by the polar dual polytope $P^o$. A fine regular star triangulation of $P^o$ defines a refined fan which corresponds to a simplicial toric variety $V$, such that a generic anti-canonical divisor $X$ is a smooth Calabi-Yau 3-fold hypersurface of $V$. The final numbers are about $X$: "H:5,20 [-30]" says that $h^{1,1}(X) = 5$ and $h^{1,2}(X) = 20$. The topological Euler characteristic of $X$ is the number in square brackets: $2 h^{1,1}(X) - 2 h^{1,2}(X) = 10 - 40 = -30$.

The first 2 integers are the dimensions of the matrix (4 by 10).

i4 : needsPackage "Polyhedra";
i5 : P = convexHull A

o5 = P

o5 : Polyhedron

$P$ is the convex hull of the columns in the $M = \ZZ^4$ lattice. $P$ has 10 vertices and 25 lattice points, explaining the part of the line "M:25 10".

i6 : LP = latticePoints P

o6 = {| -1 |, | 1 |, | 2  |, | 0 |, | 1 |, | -2 |, | 0  |, | 1  |, | 0 |, |
      | 0  |  | 0 |  | -1 |  | 1 |  | 0 |  | 2  |  | -2 |  | 0  |  | 1 |  |
      | 2  |  | 0 |  | -2 |  | 1 |  | 0 |  | 0  |  | -1 |  | -1 |  | 0 |  |
      | -2 |  | 0 |  | 0  |  | 0 |  | 1 |  | -1 |  | 2  |  | 0  |  | 0 |  |
     ------------------------------------------------------------------------
     0  |, | -1 |, | 0  |, | 0 |, | 0 |, | 0  |, | 0  |, | 0  |, | -1 |, 0, |
     -1 |  | 1  |  | -1 |  | 0 |  | 0 |  | 0  |  | -1 |  | 0  |  | 1  |     |
     -1 |  | 0  |  | 0  |  | 1 |  | 0 |  | 1  |  | 0  |  | -1 |  | 1  |     |
     1  |  | 0  |  | 1  |  | 0 |  | 1 |  | -1 |  | 0  |  | 0  |  | -1 |     |
     ------------------------------------------------------------------------
     1  |, | 1  |, | -1 |, | -1 |, | -1 |, | 0  |}
     -1 |  | -1 |  | 0  |  | 0  |  | 1  |  | 0  |
     -1 |  | -1 |  | 0  |  | 1  |  | 0  |  | 0  |
     1  |  | 0  |  | 0  |  | -1 |  | -1 |  | -1 |

o6 : List
i7 : #LP

o7 = 25
i8 : vertices P

o8 = | 1 0 2  0 0 -1 -2 0 1 0  |
     | 0 1 -1 0 1 0  2  0 0 -2 |
     | 0 0 -2 1 1 2  0  0 0 -1 |
     | 0 0 0  0 0 -2 -1 1 1 2  |

              4        10
o8 : Matrix QQ  <--- QQ
i9 : numColumns vertices P

o9 = 10

$P_2$ is the polar dual of $P$ in the $N = \ZZ^4$ lattice. $P_2$ has 9 vertices and 10 lattice points, explaining the part of the line "N:10 9".

i10 : P2 = polar P

o10 = P2

o10 : Polyhedron
i11 : LP2 = latticePoints P2

o11 = {| 0  |, | -1 |, | 1  |, | -1 |, | 0  |, | -1 |, | 0  |, | 1 |, | -1 |,
       | 0  |  | 0  |  | 0  |  | 1  |  | -1 |  | -1 |  | -1 |  | 1 |  | -1 |
       | -1 |  | -1 |  | -1 |  | -1 |  | 0  |  | 0  |  | 1  |  | 1 |  | 0  |
       | -1 |  | 0  |  | -1 |  | 0  |  | -1 |  | 0  |  | -1 |  | 1 |  | 1  |
      -----------------------------------------------------------------------
      0}

o11 : List
i12 : #LP2

o12 = 10
i13 : vertices P2

o13 = | -1 -1 -1 -1 1 0  0  0  1  |
      | -1 0  1  -1 1 -1 -1 0  0  |
      | 0  -1 -1 0  1 0  1  -1 -1 |
      | 0  0  0  1  1 -1 -1 -1 -1 |

               4        9
o13 : Matrix QQ  <--- QQ
i14 : numColumns vertices P2

o14 = 9

See also