next | previous | forward | backward | up | top | index | toc | Macaulay2 website
QuaternaryQuartics :: Hilbert scheme of 6 points in projective 3-space

Hilbert scheme of 6 points in projective 3-space -- Betti table loci

In this section, we use strongly stable ideals (Borel fixed ideals), generic initial ideals, Groebner strata, and Schreyer's algorithm for computing free resolutions, to find the components in the Hilbert scheme of 6 points, of the various Batti table loci.

Let's assume for simplicity that the field $\mathbb{k}$ has characteristic zero. This is slightly too strong an assumption for what we are doing, but if the characteristic is finite but not so small, everything we say here will hold in that case too. Let $S = \mathbb{k}[x_0, \ldots, x_n]$.

We work over a large finite field, one whose characteristic is large enough so that the subtleties of Borels over finite characteristic don't appear. We use such a finite field, instead of $\mathbb{Q}$, so that the coefficients in the ideal aren't huge. This doesn't change the answers, but we need to check that afterwords.

i1 : setRandomSeed 4332367823

o1 = 4332367823
i2 : kk = ZZ/101

o2 = kk

o2 : QuotientRing
i3 : S = kk[a,b,c,d];

Strongly stable ideals with a given Hilbert polynomial

A strongly stable monomial ideal is a monomial ideal $J$ such that if $x_i m$ is in $J$, then $x_j m$ is in $J$, for all $j < i$. In characteristic zero, this coincides with the notion of an ideal being fixed under the Borel action of upper triangular matrices. There is a more complicated combinatorial description of Borel fxied ideals in positive characteristic, this is why we simplify here to characteristic zero.

There are only finitely many saturated Borel fixed monomial ideals of a given Hilbert polynomial (this is folklore, but D. Maclagan has a nice general paper which proves a sweeping generalization of this). Alyson Reeves gave an algorithm in her Cornell thesis to compute all of the saturated Borels, with a given Hilbert polynomial. Moore and Nagel, and separately Albarelli-Lella (arxiv 1406.6924) have papers improving this construction, and the latter have implemented a Macaulay2 package which computes these.

As our running example computation, we consider the Hilbert scheme of 6 points in $\PP^3$. Here are all of the strongly stable ideals with Hilbert polynomial $p(z) = 6$ in $\PP^3$. We use the package StronglyStableIdeals written by Albarelli and Lella.

i4 : B6 = stronglyStableIdeals(6, S)

                    6                   2   5              2     2   4  
o4 = {ideal (b, a, c ), ideal (a, b*c, b , c ), ideal (a, b , b*c , c ),
     ------------------------------------------------------------------------
                3     2   2    3                     2        2   4        
     ideal (a, c , b*c , b c, b ), ideal (b*c, a*c, b , a*b, a , c ), ideal
     ------------------------------------------------------------------------
            2        2   3     2
     (a*c, b , a*b, a , c , b*c )}

o4 : List
i5 : B6 = nondegenerateBorels(6, S)

                        2        2   4                2        2   3     2
o5 = {ideal (b*c, a*c, b , a*b, a , c ), ideal (a*c, b , a*b, a , c , b*c )}

o5 : List
i6 : B6/minimalBetti

             0 1 2 3         0 1 2 3
o6 = {total: 1 6 8 3, total: 1 6 8 3}
          0: 1 . . .      0: 1 . . .
          1: . 5 6 2      1: . 4 4 1
          2: . . . .      2: . 2 4 2
          3: . 1 2 1

o6 : List
i7 : matrix for J in B6 list for d to 6 list hilbertFunction(d, J)

o7 = | 1 4 5 6 6 6 6 |
     | 1 4 6 6 6 6 6 |

              2        7
o7 : Matrix ZZ  <--- ZZ

Notice that each saturated Borel fixed ideal with this Hilbert polynomial has a different Hilbert function.

Generic initial ideals

There are two key theorems (see Eisenbud's commutative algebra book, for an exposition) that we use here:

Theorem(Galligo, Bayer-Stillman) After a general change of coordinates, the initial ideal $J = in(g.I)$, under any term order, is Borel fixed (and hence, in characteristic zero, is strongly stable).

Theorem(Bayer-Stillman) The initial ideal $J = in(g.I)$, under graded reverse lex order, has the same depth, projective dimension and regularity as $I$. In characteristic zero, the regularity of $I$ is precisely the maximal degree of a Groebner basis generator of $g.I$.

In particular, after a general, or sufficiently random, change of coordinates, the initial ideal $J$ is saturated, Borel fixed, and has the same regularity and projective dimension as $I$.

For example, if we take a random set of points, the resulting initial ideal in graded reverse lex order is strongly stable (it is strongly stable for any order).

i8 : I = pointsIdeal randomPoints(S, 6)

                             2                              2   2          
o8 = ideal (a*c - 33b*c - 37c  + 48a*d + 41b*d - 12c*d - 25d , b  + 44b*c -
     ------------------------------------------------------------------------
        2                              2                   2                
     17c  + 15a*d - 41b*d - 49c*d + 42d , a*b + 49b*c + 11c  - 17a*d + 17b*d
     ------------------------------------------------------------------------
                  2   2              2                              2
     + 47c*d + 47d , a  - 35b*c + 13c  - 19a*d - 20b*d + 37c*d + 18d )

o8 : Ideal of S
i9 : degree I

o9 = 6
i10 : hilbertPolynomial(I, Projective => false)

o10 = 6

o10 : QQ[i]
i11 : J = monomialIdeal leadTerm I

                      2        2          2   3
o11 = monomialIdeal (a , a*b, b , a*c, b*c , c )

o11 : MonomialIdeal of S
i12 : isBorel J

o12 = true
i13 : betti res I

             0 1 2 3
o13 = total: 1 4 5 2
          0: 1 . . .
          1: . 4 2 .
          2: . . 3 2

o13 : BettiTally

The Groebner family of an initial ideal

Given a monomial ideal $J$, and a term order (we generally always take the graded reverse lex order), we can form a parameter space of ideals having initial ideal $J$. For each minimal generator $x^\alpha$ of $J$, consider the set $x^\gamma$ of monomials of the same degree, not in $J$. For each such $\alpha$, form a polynomial

$\phantom{WWWWW} F_\alpha = x^\alpha + \sum_\gamma t_{\alpha, \gamma} x^\gamma $

Let $U = T[x_0, \ldots, x_n]$, where $T = \mathbb{k}[t_{\alpha, \gamma}]$ is the polynomial ring generateds by all variables of the form $t_{\alpha, \gamma}$ as above. Let $F$ be the ideal in $U$ generated by the $F_\alpha$. $F = (F_\alpha)$ is called the Groebner family of $J$.

Any term order $>$ on the monomials of $S$, on a finite set $M$ of monomials, is given by a weight vector $w \in \mathbb{Z}^{n+1}$: for $x^\alpha, x^\beta \in M$, $x^\alpha > x^\beta$ if and only if $w \cdot \alpha > w \cdot \beta$. If we let the weight of $t_{\alpha, \gamma}$ be $w \cdot (\alpha - \gamma)$, then with this grading, $F_\alpha$ is homogeneous of weight $w \cdot \alpha$. This grading is useful for performance reasons: computing with homogeneous ideals is much more efficient than with arbitrary ideals. Additionally, we can order the variables $t_{\alpha, \gamma}$ by refining the weight degree by any term order on $T$: if the weight of $t_{\alpha, \gamma}$ is greater than $t_{\alpha', \gamma'}$ then $t_{\alpha, \gamma} > t_{\alpha', \gamma'}$ in this term order. weight.

The Groebner stratum of an initial ideal

If we consider a minimal set of syzygies of the minimal generators $x^\alpha$ of $J$, and we apply this syzygy to the $F_\alpha$, then take the remainder upon division with the $F_\alpha$, and let $L$ be the ideal generated by all of the coefficients in $T$ of these resulting polynomials, then $L$ is called the Groebner stratum of $J$, and $F = (F_\alpha)$ is called the Groebner family of $J$.

Over $\mathbb{V}(L)$, $F$ defines a flat family all of whose fibers have initial ideal $J$, and consequently defines via representability of the Hilbert scheme, a closed subscheme of $Hilb$. These families, over all saturated monomial ideals, cover the Hilbert scheme.

i14 : needsPackage "GroebnerStrata"

o14 = GroebnerStrata

o14 : Package
i15 : J = B6_1

                   2        2   3     2
o15 = ideal (a*c, b , a*b, a , c , b*c )

o15 : Ideal of S
i16 : J = ideal(a^2,a*b,b^2,a*c,b*c^2,c^3)

              2        2          2   3
o16 = ideal (a , a*b, b , a*c, b*c , c )

o16 : Ideal of S
i17 : F = groebnerFamily J

              2                      2                      2               
o17 = ideal (a  + t b*c + t a*d + t c  + t b*d + t c*d + t d , a*b + t b*c +
                   1       3       2      4       5       6           7     
      -----------------------------------------------------------------------
                 2                         2   2                         2  
      t a*d + t c  + t  b*d + t  c*d + t  d , b  + t  b*c + t  a*d + t  c  +
       9       8      10       11       12          13       15       14    
      -----------------------------------------------------------------------
                            2                              2           
      t  b*d + t  c*d + t  d , a*c + t  b*c + t  a*d + t  c  + t  b*d +
       16       17       18           19       21       20      22     
      -----------------------------------------------------------------------
                   2     2                    2       2          2         2
      t  c*d + t  d , b*c  + t  b*c*d + t  a*d  + t  c d + t  b*d  + t  c*d 
       23       24            25         27        26       28        29    
      -----------------------------------------------------------------------
            3   3                    2       2          2         2       3
      + t  d , c  + t  b*c*d + t  a*d  + t  c d + t  b*d  + t  c*d  + t  d )
         30          31         33        32       34        35        36

o17 : Ideal of kk[t , t  , t , t  , t  , t , t  , t  , t  , t , t  , t , t  , t  , t , t  , t  , t  , t , t  , t , t  , t  , t  , t , t  , t  , t  , t  , t  , t  , t  , t  , t  , t  , t  ][a..d]
                   6   12   5   30   24   4   18   36   11   2   29   3   10   23   1   17   28   35   8   22   9   16   26   34   7   20   27   14   21   25   32   19   15   33   13   31
i18 : U = ring F;
i19 : T = coefficientRing U

o19 = T

o19 : PolynomialRing
i20 : netList F_*

      +--------------------------------------------------------------+
      | 2                      2                      2              |
o20 = |a  + t b*c + t a*d + t c  + t b*d + t c*d + t d               |
      |      1       3       2      4       5       6                |
      +--------------------------------------------------------------+
      |                         2                         2          |
      |a*b + t b*c + t a*d + t c  + t  b*d + t  c*d + t  d           |
      |       7       9       8      10       11       12            |
      +--------------------------------------------------------------+
      | 2                         2                         2        |
      |b  + t  b*c + t  a*d + t  c  + t  b*d + t  c*d + t  d         |
      |      13       15       14      16       17       18          |
      +--------------------------------------------------------------+
      |                            2                         2       |
      |a*c + t  b*c + t  a*d + t  c  + t  b*d + t  c*d + t  d        |
      |       19       21       20      22       23       24         |
      +--------------------------------------------------------------+
      |   2                    2       2          2         2       3|
      |b*c  + t  b*c*d + t  a*d  + t  c d + t  b*d  + t  c*d  + t  d |
      |        25         27        26       28        29        30  |
      +--------------------------------------------------------------+
      | 3                    2       2          2         2       3  |
      |c  + t  b*c*d + t  a*d  + t  c d + t  b*d  + t  c*d  + t  d   |
      |      31         33        32       34        35        36    |
      +--------------------------------------------------------------+
i21 : L = trim groebnerStratum F;

o21 : Ideal of T
i22 : assert(dim L == 18)
i23 : elapsedTime isPrime L
 -- 4.38761 seconds elapsed

o23 = true

The Schreyer resolution and minimal Betti numbers

Schreyer's construction of a nonminimal free resolution starts with a Groebner basis. First, one constructs the Schreyer frame (see La Scala, Stillman). This is determined solely from the initial ideal $J$ and its minimal generators (but depends on some choices of ordering, but otherwise is combinatorial). This consists of the lead monomials of the Groebner bases of the syzygy modules of the initial ideal $J$ (in the so-called induces, or Schreyer order).

One then fills in the rest of each column of each matrix in this non minimal resolution by computing the image of the monomial, and taking its remainder with respect to all the lead terms at the previous homological degree (except the monomial we used). This gives a nonminimal free resolution, and after the frame is made, the only operations needed in the coefficient ring are subtraction and multiplication.

By linear algebra, a non minimal free resolution can be made minimal by the following process: find a non-zero scalar entry at, say, the $(i,j)$ entry of the $\partial_k : C_k \to C_{k-1}$. By column operations, make all the other entries in the $i$-th row 0, then remove the $i$-th row, and $j$-th column of this matrix, changing the two adjacent matrices in the process.

In the standard grading on $S$, the minimal free resolution will be homogeneous (with the $t$ variables all having degree 0). For each degree $d$, there is a submatrix of the map $\partial^C_i \colon C_i \to C_{i-1}$, let's call it $\rho_{i,d}$. This is a matrix defined over the base field. The ranks of these matrices determine the Betti table of the minimal free resolution of $S/I$.

Similarly, one can compute the non-minimal resolution of $F$, over the ring $T/L$. For any specialization to a point, the specialization of the complex is a non-minimal free resolution of the specialized point.

There are only two Borel fixed ideals for 6 points. Notice that in this particular case, the Hilbert function and generic initial ideal is determined by the number of quadrics in the saturated ideal: If there are 5 quadrics in the ideal, it has the first gin, and if there are 4 quadrics, it has the second gin.

This means that we can partition the entire Hilbert scheme into 2 parts: The generic initial ideal is one of these two.

Let $H$ be the Hilbert scheme of 6 points in ${\mathbb P}^3$. $H$ has one component, is rational, and has dimension 18. A general set of 6 points has regularity 2, and its free resolution is shown in the next example.

i24 : I = pointsIdeal randomPoints(S, 6)

                             2                              2   2          
o24 = ideal (a*c - 7b*c - 49c  + 40a*d - 42b*d + 12c*d + 28d , b  - 36b*c -
      -----------------------------------------------------------------------
         2                              2                  2                 
      18c  - 22a*d + 20b*d + 37c*d - 18d , a*b - 8b*c - 28c  + 6a*d + 20b*d -
      -----------------------------------------------------------------------
         2   2             2                             2
      26d , a  - 18b*c - 3c  + 15a*d - 4b*d - 21c*d + 30d )

o24 : Ideal of S
i25 : degree I

o25 = 6
i26 : radical I == I

o26 = true
i27 : betti res I

             0 1 2 3
o27 = total: 1 4 5 2
          0: 1 . . .
          1: . 4 2 .
          2: . . 3 2

o27 : BettiTally

If an ideal $I$ has initial ideal $J$, we can construct a (nonminimal in general) free resolution of $I$ with the same Betti table as $J$. The Betti table of (the minimal free resolution of) $I$ is determined by the ranks of the degree 0 maps in this non-minimal resolution.

i28 : (CF, H) = nonminimalMaps F;
i29 : U = ring CF

o29 = U

o29 : PolynomialRing
i30 : CF

       1      6      10      6      1
o30 = U  <-- U  <-- U   <-- U  <-- U
                                    
      0      1      2       3      4

o30 : ChainComplex
i31 : betti(CF, Weights=>{1}) -- alas, it is a poor non-minimal resolution

             0 1  2 3 4
o31 = total: 1 6 10 6 1
          0: 1 .  . . .
          1: . 4  4 2 .
          2: . 2  5 3 1
          3: . .  1 1 .

o31 : BettiTally
i32 : assert isHomogeneous CF -- but it is homogeneous, as it needs to be.
i33 : keys H

o33 = {(3, 4), (3, 5), (4, 6), (2, 3)}

o33 : List
i34 : M1 = H#(2,3) -- rank is 0, 1, or 2.

o34 = {3} | -t_8-t_14t_19      t_7t_14-t_20t_14+t_14t_19t_13            
      {3} | -t_7+t_20-t_19t_13 -t_8-t_14t_19+t_7t_13-t_20t_13+t_19t_13^2
      -----------------------------------------------------------------------
      -t_2-t_20^2+t_14t_19^2    -t_8t_20+t_1t_14+t_7t_14t_19             |
      -t_1-2t_20t_19+t_19^2t_13 -t_2-t_7t_20-t_8t_19+t_1t_13+t_7t_19t_13 |

              2       4
o34 : Matrix T  <--- T
i35 : M2 = H#(3,4) -- rank is 1 or 2

o35 = {4} | -t_14                                   
      {4} | -1                                      
      {4} | t_8+t_14t_19-t_7t_13+t_20t_13-t_19t_13^2
      {4} | -t_7+t_20-t_19t_13                      
      {4} | 0                                       
      -----------------------------------------------------------------------
      -t_8                                    |
      t_19                                    |
      t_2+t_7t_20+t_8t_19-t_1t_13-t_7t_19t_13 |
      -t_1-2t_20t_19+t_19^2t_13               |
      t_7-t_20+t_19t_13                       |

              5       2
o35 : Matrix T  <--- T
i36 : M3 = H#(3,5) -- maximal rank, can ignore

o36 = {5} | -1 t_19 -t_20 |

              1       3
o36 : Matrix T  <--- T
i37 : M4 = H#(4,6) -- maximal rank, can ignore

o37 = {6} | -1 |

              1       1
o37 : Matrix T  <--- T

What are the possible ranks of M1, M2? (M3, M4 are full rank). We check: M1 is rank 0 (on the relevant points of the parameter space) if and only if M2 has rank 1 (the smallest possible). So we need to check: (rank M1, rank M2) = (0, 1), (0,2), (1,1), (1,2), (2,1), (2,2)). Of these,

i38 : ideal M1 == minors(2, M2)

o38 = true

Therefore the following cannot happen: (0, 2), (1, 1), (2, 1). Therefore the possible ranks are: (0, 1), (1,2), (2,2). The last one means there is maximal cancellation: this happens for an open set of the Hilbert scheme of 6 points. (0,1) means: no cancellation, whereas (1,2) means

$\phantom{WWWW} \begin{matrix} &0&1&2&3\\ \text{total:}&1&6&8&3\\ \text{0:}&1&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&4&1\\ \text{2:}&\text{.}&2&4&2\\ \end{matrix},\quad \begin{matrix} &0&1&2&3\\ \text{total:}&1&5&6&2\\ \text{0:}&1&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&3&\text{.}\\ \text{2:}&\text{.}&1&3&2\\ \end{matrix},\quad \begin{matrix} &0&1&2&3\\ \text{total:}&1&4&5&2\\ \text{0:}&1&\text{.}&\text{.}&\text{.}\\ \text{1:}&\text{.}&4&2&\text{.}\\ \text{2:}&\text{.}&\text{.}&3&2\\ \end{matrix} $

We now compute the locus in $V(L)$ where the Betti diagram has no cancellation. This is a closed subscheme of $V(L)$, which is a closed subscheme of the Hilbert scheme. Notice that there are two components.

i39 : L441 = trim(L + ideal M1);

o39 : Ideal of T
i40 : elapsedTime compsL441 = decompose L441;
 -- 2.24258 seconds elapsed
i41 : #compsL441

o41 = 2
i42 : compsL441/dim -- two components, of dimensions 14 and 16.

o42 = {16, 14}

o42 : List
i43 : compsL441/dim == {16, 14}

o43 = true

Both components are rational, and here are random points, one on each component:

i44 : pta = randomPointOnRationalVariety compsL441_0

o44 = | -27 -13 45 -25 3 38 -20 -30 -41 25 -26 -44 -31 5 14 2 -45 45 21 -27
      -----------------------------------------------------------------------
      -23 -29 34 49 32 19 10 26 19 37 15 -28 -50 -10 -32 18 |

               1        36
o44 : Matrix kk  <--- kk
i45 : Fa = sub(F, (vars S) | pta)

              2              2                              2               
o45 = ideal (a  + 14b*c + 25c  - 44a*d + 38b*d + 45c*d - 27d , a*b + 32b*c +
      -----------------------------------------------------------------------
         2                              2   2              2                
      21c  - 23a*d - 31b*d - 41c*d - 13d , b  - 32b*c + 26c  - 50a*d - 29b*d
      -----------------------------------------------------------------------
                  2                   2                            2     2  
      + 2c*d - 20d , a*c - 28b*c + 19c  + 19a*d - 27b*d + 5c*d + 3d , b*c  +
      -----------------------------------------------------------------------
                   2         2        2        2      3   3                2 
      37b*c*d + 34c d + 10a*d  - 45b*d  - 26c*d  - 25d , c  + 18b*c*d + 15c d
      -----------------------------------------------------------------------
             2        2        2      3
      - 10a*d  + 49b*d  + 45c*d  - 30d )

o45 : Ideal of S
i46 : betti res Fa

             0 1 2 3
o46 = total: 1 6 8 3
          0: 1 . . .
          1: . 4 4 1
          2: . 2 4 2

o46 : BettiTally
i47 : netList decompose Fa -- this one is 5 points on a plane, and another point

      +--------------------------------------------------------------------------------------------------------------------------------------------------------------+
o47 = |ideal (c + 19d, b - 37d, a + 4d)                                                                                                                              |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                             2              2                      2   3                2         2        2      3     2                2         2        2 |
      |ideal (a - 28b + 19c + 48d, b  - 32b*c + 26c  - 15b*d + 43c*d - 44d , c  + 18b*c*d + 15c d - 29b*d  + 33c*d  + 46d , b*c  + 37b*c*d + 34c d + 33b*d  - 14c*d )|
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------+
i48 : CFa = minimalPrimes Fa

                                                                      2  
o48 = {ideal (c + 19d, b - 37d, a + 4d), ideal (a - 28b + 19c + 48d, b  -
      -----------------------------------------------------------------------
                 2                      2   3                2         2  
      32b*c + 26c  - 15b*d + 43c*d - 44d , c  + 18b*c*d + 15c d - 29b*d  +
      -----------------------------------------------------------------------
           2      3     2                2         2        2
      33c*d  + 46d , b*c  + 37b*c*d + 34c d + 33b*d  - 14c*d )}

o48 : List
i49 : lin = CFa_1_0 -- a linear form, defining a plane.

o49 = a - 28b + 19c + 48d

o49 : S
i50 : CFa/degree

o50 = {1, 5}

o50 : List
i51 : CFa/(I -> lin % I == 0) -- so 5 points on the plane.

o51 = {false, true}

o51 : List
i52 : degree(Fa : (Fa : lin))  -- somewhat simpler(?) way to see the ideal of the 5 points

o52 = 5
i53 : ptb = randomPointOnRationalVariety compsL441_1

o53 = | 31 42 28 25 19 3 43 -7 -3 -42 -29 -29 14 2 50 5 36 -13 -42 47 13 31
      -----------------------------------------------------------------------
      -37 -23 -24 -4 38 -29 -23 21 17 9 0 21 -9 -47 |

               1        36
o53 : Matrix kk  <--- kk
i54 : Fb = sub(F, (vars S) | ptb)

              2              2                             2               
o54 = ideal (a  + 50b*c - 42c  - 29a*d + 3b*d + 28c*d + 31d , a*b - 24b*c -
      -----------------------------------------------------------------------
         2                             2   2             2                 
      42c  + 13a*d + 14b*d - 3c*d + 42d , b  - 9b*c - 29c  + 31b*d + 5c*d +
      -----------------------------------------------------------------------
         2                 2                             2     2            
      43d , a*c + 9b*c - 4c  - 23a*d + 47b*d + 2c*d + 19d , b*c  + 21b*c*d -
      -----------------------------------------------------------------------
         2         2        2        2      3   3                2         2
      37c d + 38a*d  + 36b*d  - 29c*d  + 25d , c  - 47b*c*d + 17c d + 21a*d 
      -----------------------------------------------------------------------
             2        2     3
      - 23b*d  - 13c*d  - 7d )

o54 : Ideal of S
i55 : betti res Fb

             0 1 2 3
o55 = total: 1 6 8 3
          0: 1 . . .
          1: . 4 4 1
          2: . 2 4 2

o55 : BettiTally
i56 : netList decompose Fb --

      +-------------------------------------------------------+
o56 = |ideal (c - 45d, b + 16d, a + 38d)                      |
      +-------------------------------------------------------+
      |ideal (c + 43d, b + 10d, a + 8d)                       |
      +-------------------------------------------------------+
      |ideal (c + 34d, b + 15d, a + 28d)                      |
      +-------------------------------------------------------+
      |ideal (c + 11d, b + 39d, a + 23d)                      |
      +-------------------------------------------------------+
      |                                      2              2 |
      |ideal (b - 32c + 42d, a - 19c - 16d, c  - 28c*d - 40d )|
      +-------------------------------------------------------+
i57 : netList for x in subsets(decompose Fb, 3) list intersect(x#0, x#1, x#2)

      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                          2                      2                         2   2                      2                                                                                                             |
o57 = |ideal (a - 7b + 32c + d, c  + 42b*d + 33c*d - 10d , b*c - b*d + 13c*d + 18d , b  + 28b*d - 32c*d + 16d )                                                                                                            |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                          2                      2                           2   2                      2                                                                                                           |
      |ideal (a - 7b + 32c + d, c  + 40b*d - 36c*d + 33d , b*c + 45b*d - 16c*d + 39d , b  - 20b*d + 29c*d + 38d )                                                                                                          |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                          2                      2                           2   2                     2                                                                                                            |
      |ideal (a - 7b + 32c + d, c  - 10b*d + 17c*d - 21d , b*c - 17b*d - 23c*d - 32d , b  - 8b*d - 12c*d - 46d )                                                                                                           |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                                     3      2         2      3                                                                                                                                                      |
      |ideal (b + 23c - 11d, a - 9c + 25d, c  - 13c d - 14c*d  + 23d )                                                                                                                                                     |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                                     2                      2   2      2                      2   3      2         2        2      3                                                                                |
      |ideal (a + 48b - 40c - 20d, b*c - 32c  + 43b*d - 21c*d - 12d , b  - 14c  + 14b*d + 18c*d + 36d , c  + 28c d - 20b*d  + 42c*d  - 50d )                                                                               |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                                   2                      2   2      2                      2   3      2         2        2     3                                                                                   |
      |ideal (a + b + 50c + 26d, b*c - 32c  + 34b*d - 36c*d + 14d , b  - 14c  + 34b*d - 16c*d - 33d , c  + 28c d + 39b*d  - 28c*d  + 4d )                                                                                  |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |        2                            2                                 2                                 2   2                              2                                  2   2                              2 |
      |ideal (c  - 7a*d - 19b*d + 6c*d - 19d , b*c - 5a*d + 49b*d - 4c*d + 50d , a*c - 6a*d + 35b*d - 39c*d - 2d , b  - 46a*d + 22b*d + 42c*d + 43d , a*b + 3a*d - 12b*d - 49c*d + 40d , a  + 28a*d - 13b*d - 25c*d - 35d )|
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |                                     2                     2   2      2                      2   3      2         2        2     3                                                                                  |
      |ideal (a - 46b + 39c - 29d, b*c - 32c  + 11b*d - 7c*d - 43d , b  - 14c  + 29b*d + 43c*d - 41d , c  + 28c d + 46b*d  - 50c*d  - 5d )                                                                                 |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |        2                              2                                2                                   2   2                              2                                 2   2                           2  |
      |ideal (c  + 15a*d + 27b*d + 35c*d + 46d , b*c - 6a*d + b*d + 36c*d - 31d , a*c - 10a*d + 45b*d + 20c*d - 23d , b  - 23a*d + 15b*d + 31c*d - 13d , a*b - 6a*d - 40b*d + 8c*d + 18d , a  - 8a*d - 24b*d + c*d - 22d ) |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
      |        2                              2                                2                                  2   2                      2                                   2   2                              2      |
      |ideal (c  + 37a*d + 25b*d - 16c*d + 14d , b*c - 7a*d + 47b*d - 3c*d - 2d , a*c - 14a*d + 27b*d - 35c*d - 8d , b  - 33b*d + 19c*d + 27d , a*b - 15a*d - 30b*d - 40c*d - 24d , a  - 44a*d + 16b*d + 11c*d + 12d )     |
      +--------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
i58 : pt0 = randomPointOnRationalVariety(compsL441_0)

o58 = | 13 17 -19 -1 -9 -15 -28 -39 -36 1 -47 29 37 -40 35 -31 12 -21 -8 -13
      -----------------------------------------------------------------------
      14 15 -23 39 11 8 -24 -13 -42 -2 18 46 -18 -29 -33 -22 |

               1        36
o58 : Matrix kk  <--- kk
i59 : pt1 = randomPointOnRationalVariety(compsL441_1)

o59 = | -45 18 -9 38 21 29 50 -8 -5 45 -47 -26 37 -35 -21 28 27 46 -17 -49
      -----------------------------------------------------------------------
      -23 15 -50 37 -39 -14 21 10 -31 3 -18 32 0 3 -15 33 |

               1        36
o59 : Matrix kk  <--- kk

We compute the ideal of the corresponding zero dimensional scheme with length 6, corresponding to the points pt0, pt1 in Hilb.

i60 : I0 = sub(sub(F, (vars ring F) | sub(pt0, ring F)), S)

              2            2                              2               
o60 = ideal (a  + 35b*c + c  + 29a*d - 15b*d - 19c*d + 13d , a*b + 11b*c -
      -----------------------------------------------------------------------
        2                              2   2              2                  
      8c  + 14a*d + 37b*d - 36c*d + 17d , b  - 33b*c - 13c  - 18a*d + 15b*d -
      -----------------------------------------------------------------------
                 2                  2                             2     2  
      31c*d - 28d , a*c + 46b*c + 8c  - 42a*d - 13b*d - 40c*d - 9d , b*c  -
      -----------------------------------------------------------------------
                  2         2        2        2    3   3                2   
      2b*c*d - 23c d - 24a*d  + 12b*d  - 47c*d  - d , c  - 22b*c*d + 18c d -
      -----------------------------------------------------------------------
           2        2        2      3
      29a*d  + 39b*d  - 21c*d  - 39d )

o60 : Ideal of S
i61 : I1 = sub(sub(F, (vars ring F) | sub(pt1, ring F)), S)

              2              2                             2               
o61 = ideal (a  - 21b*c + 45c  - 26a*d + 29b*d - 9c*d - 45d , a*b - 39b*c -
      -----------------------------------------------------------------------
         2                             2   2              2                  
      17c  - 23a*d + 37b*d - 5c*d + 18d , b  - 15b*c + 10c  + 15b*d + 28c*d +
      -----------------------------------------------------------------------
         2                   2                              2     2         
      50d , a*c + 32b*c - 14c  - 31a*d - 49b*d - 35c*d + 21d , b*c  + 3b*c*d
      -----------------------------------------------------------------------
           2         2        2        2      3   3                2        2
      - 50c d + 21a*d  + 27b*d  - 47c*d  + 38d , c  + 33b*c*d - 18c d + 3a*d 
      -----------------------------------------------------------------------
             2        2     3
      + 37b*d  + 46c*d  - 8d )

o61 : Ideal of S
i62 : betti res I0

             0 1 2 3
o62 = total: 1 6 8 3
          0: 1 . . .
          1: . 4 4 1
          2: . 2 4 2

o62 : BettiTally
i63 : betti res I1

             0 1 2 3
o63 = total: 1 6 8 3
          0: 1 . . .
          1: . 4 4 1
          2: . 2 4 2

o63 : BettiTally
i64 : netList decompose I0

      +---------------------------------------------------------------------------------------------+
o64 = |ideal (c - 42d, b - 6d, a + 41d)                                                             |
      +---------------------------------------------------------------------------------------------+
      |ideal (c + 38d, b - 41d, a - 41d)                                                            |
      +---------------------------------------------------------------------------------------------+
      |                                  2                      2   2      2                      2 |
      |ideal (a + 46b + 8c - 7d, b*c - 7c  + 13b*d + 16c*d - 21d , b  - 42c  - 41b*d + 35c*d - 39d )|
      +---------------------------------------------------------------------------------------------+
i65 : netList decompose I1

      +------------------------------------------------------+
o65 = |ideal (c + 32d, b + 18d, a - 33d)                     |
      +------------------------------------------------------+
      |ideal (c + 29d, b - 8d, a + 50d)                      |
      +------------------------------------------------------+
      |ideal (c + 16d, b + 39d, a - 32d)                     |
      +------------------------------------------------------+
      |ideal (c + 5d, b - 14d, a + 7d)                       |
      +------------------------------------------------------+
      |                                     2              2 |
      |ideal (b - 40c + 5d, a - 47c + 24d, c  - 27c*d + 15d )|
      +------------------------------------------------------+
i66 : L430 = (trim minors(2, M1)) + groebnerStratum F;

o66 : Ideal of T
i67 : C = res(I, FastNonminimal => true)

       1      4      5      2
o67 = S  <-- S  <-- S  <-- S  <-- 0
                                   
      0      1      2      3      4

o67 : ChainComplex
i68 : betti C

             0 1 2 3
o68 = total: 1 4 5 2
          0: 1 . . .
          1: . 4 2 .
          2: . . 3 2

o68 : BettiTally
i69 : m1 = submatrixByDegrees(C.dd_2, {3}, {3})

o69 = 0

                     2
o69 : Matrix 0 <--- S
i70 : m2 = submatrixByDegrees(C.dd_3, {4}, {4})

o70 = 0

              3
o70 : Matrix S  <--- 0

In this example, m1 and m2 both have full rank, and therefore we can cancel adjacent numbers to get a minimal resolution (it must be minimal, as by homogeneity, there are no non-zero elements of degree 0 in the resulting resolution.

i71 : minimalBetti I

             0 1 2 3
o71 = total: 1 4 5 2
          0: 1 . . .
          1: . 4 2 .
          2: . . 3 2

o71 : BettiTally

Schreyer's algorithm implies that if we have a Groebner basis of an ideal with gin $B$, then we can construct a nonminimal resolution of $S/I$ whose Betti table matches that of $B$. This will be nonminimal, therefore can be pruned to a free resolution by taking any non-zero scalars that appear as entries in the resolution, and performing linear algebra to remove that entry, its row and column, and the corresponding column in the previous matrix then we still have a free resolution. Continuing in this way, we obtain a minimal resolution.