detectCongruence(SpecialGushelMukaiFourfold,ZZ) -- detect and return a congruence of (2e-1)-secant curves of degree e inside a del Pezzo fivefold

Synopsis

Function: detectCongruence
Usage:

detectCongruence X

detectCongruence(X,e)
Inputs:
- X, a special Gushel-Mukai fourfold, containing a surface $S\subset Y$, where $Y$ denotes the unique del Pezzo fivefold containing the fourfold $X$
- e, an integer, a positive integer (optional but recommended)
Optional inputs:
- Verbose => ..., default value false, request verbose feedback
Outputs:
- a congruence of curves, that is a function which takes a (general) point $p\in Y$ and returns the unique rational curve of degree $e$, $(2e-1)$-secant to $S$, contained in $Y$ and passing through $p$ (an error is thrown if such a curve does not exist or is not unique)

Description

i1 : -- A GM fourfold of discriminant 20
     X = specialGushelMukaiFourfold("17",ZZ/33331);

o1 : ProjectiveVariety, GM fourfold containing a surface of degree 9 and sectional genus 2

i2 : describe X

o2 = Special Gushel-Mukai fourfold of discriminant 20
     containing a surface in PP^8 of degree 9 and sectional genus 2
     cut out by 19 hypersurfaces of degree 2
     and with class in G(1,4) given by 6*s_(3,1)+3*s_(2,2)
     Type: ordinary
     (case 17 of Table 1 in arXiv:2002.07026)

i3 : time f = detectCongruence(X,Verbose=>true);
number lines contained in the image of the quadratic map and passing through a general point: 7
number 1-secant lines = 6
number 3-secant conics = 1
     -- used 24.9438 seconds

o3 : Congruence of 3-secant conics to surface in a fivefold in PP^8

i4 : Y = ambientFivefold X; -- del Pezzo fivefold containing X

o4 : ProjectiveVariety, 5-dimensional subvariety of PP^8

i5 : p := point Y -- random point on Y

o5 = point of coordinates [7214, -1460, 7057, -2440, 15907, -14345, -5937, 13402, 1]

o5 : ProjectiveVariety, a point in PP^8

i6 : time C = f p; -- 3-secant conic to the surface
     -- used 0.711592 seconds

o6 : ProjectiveVariety, curve in PP^8 (subvariety of codimension 4 in Y)

i7 : S = surface X;

o7 : ProjectiveVariety, surface in PP^8 (subvariety of codimension 3 in Y)

i8 : assert(dim C == 1 and degree C == 2 and dim(C*S) == 0 and degree(C*S) == 3 and isSubset(p,C) and isSubset(C,Y))

Ways to use this method: