# Example: generalized flag varieties

Let $G$ be a reductive complex Lie group and $P$ a parabolic subgroup containing a maximal torus $T$. The generalized flag variety $G/P$ is a GKM variety with the action of $T$. This package allows users to create a generalized flag variety for classical Lie types ($A$, $B$, $C$, and $D$) as a GKMVariety with conventions explicitly laid out as follows.

For type $A_{n-1}$, the group $G$ is $GL_{n}$, and the torus $T$ is $diag(t_1, \ldots, t_n)$, the group of invertible diagonal matrices.

For type $B_n$, the group $G$ is $SO_{2n+1}$, where we set the standard symmetric bilinear form on $\mathbb C^{2n+1}$ to be is given by the matrix $$\begin{pmatrix} 0 & I_n & 0 \\ I_n & 0 & 0 \\ 0 & 0 & 1 \end{pmatrix}$$ and the torus $T$ is $diag(t_1, \ldots,t_n, t_1^{-1}, \ldots, t_n^{-1}, 1)$.

For type $C_n$, the group $G$ is $Sp_{2n}$, where we set the standard alternating bilinear form on $\mathbb C^{2n}$ to be given by the matrix $$\begin{pmatrix} 0 & -I_n \\ I_n & 0 \end{pmatrix}$$ and the torus $T$ is $diag(t_1, \ldots,t_n, t_1^{-1}, \ldots, t_n^{-1})$.

For type $D_n$, the group $G$ is $SO_{2n}$, where we set the standard symmetric bilinear form on $\mathbb C^{2n}$ to be given by the matrix $$\begin{pmatrix} 0 & I_n \\ I_n & 0 \end{pmatrix}$$ and the torus $T$ is $diag(t_1, \ldots,t_n, t_1^{-1} \ldots, t_n^{-1})$.

In all the cases, the standard action of $(\mathbb C^*)^m$ on $\mathbb C^m$ is defined by $(t_1, \ldots, t_m) \cdot (x_1, \ldots, x_m) = (t_1^{-1}x_1, \ldots, t_m^{-1}x_m)$.

Let $\{w_1, \ldots, w_n\}$ be a set of fundamental weights, which for classical Lie types are explicitly set to be as follows:

($A_{n-1}$): $\{w_1, \ldots, w_n\}= \{e_1, e_1+e_2, \ldots , e_1+e_2+\cdots+e_{n-1}\}$

($B_n$): $\{w_1, \ldots, w_n\}= \{e_1, e_1+e_2, \ldots , e_1+\cdots+e_{n-1}, (1/2)(e_1+\cdots e_n)\}$

($C_n$): $\{w_1, \ldots, w_n\}= \{e_1, e_1+e_2, \ldots , e_1+\cdots+e_{n-1}, e_1 + \cdots +e_n\}$

($D_n$): $\{w_1, \ldots, w_n\}= \{e_1, e_1+e_2, \ldots , e_1+\cdots+e_{n-2}, (1/2)(e_1+\cdots+e_{n-2} +e_{n-1}- e_{n}), (1/2)(e_1+\cdots+e_{n-2}+e_{n-1}+e_n)\}$

For a sequence $(a_1, \ldots, a_n)\in \mathbb N^n$ of nonnegative integers, let $I = \{i \mid a_i \neq 0\}$ and $P_I$ the corresponding parabolic subgroup of $G$. Then the generalized flag variety $G/P_I$ is embedded in the irreducible representation of $G$ with the highest weight $a_1w_1 + \cdots a_nw_n$. These generalized flag varieties can be created as a GKMVariety using the method generalizedFlagVariety. For instance, the Grassmannian $Gr(2,4)$ of 2-dimensional subspaces in $\mathbb C^4$, embedded in $\mathbb P^5$ by the usual Plücker embedding, can be created as follows.

 i1 : Gr24 = generalizedFlagVariety("A",3,{2}) o1 = a "GKM variety" with an action of a 4-dimensional torus o1 : GKMVariety i2 : peek Gr24 o2 = GKMVariety{cache => CacheTable{...2...} } characterRing => ZZ[T ..T ] 0 3 charts => HashTable{{set {0, 1}} => {{0, -1, 1, 0}, {0, -1, 0, 1}, {-1, 0, 1, 0}, {-1, 0, 0, 1}}} {set {0, 2}} => {{0, 1, -1, 0}, {0, 0, -1, 1}, {-1, 1, 0, 0}, {-1, 0, 0, 1}} {set {0, 3}} => {{0, 1, 0, -1}, {0, 0, 1, -1}, {-1, 1, 0, 0}, {-1, 0, 1, 0}} {set {1, 2}} => {{1, 0, -1, 0}, {1, -1, 0, 0}, {0, 0, -1, 1}, {0, -1, 0, 1}} {set {1, 3}} => {{1, 0, 0, -1}, {1, -1, 0, 0}, {0, 0, 1, -1}, {0, -1, 1, 0}} {set {2, 3}} => {{1, 0, 0, -1}, {1, 0, -1, 0}, {0, 1, 0, -1}, {0, 1, -1, 0}} momentGraph => a "moment graph" on 6 vertices with 12 edges points => {{set {0, 1}}, {set {0, 2}}, {set {0, 3}}, {set {1, 2}}, {set {1, 3}}, {set {2, 3}}}

The MomentGraph of $Gr(2,4)$ is the 1-skeleton of the hypersimplex $\Delta(2,4)$, a.k.a. the octahedron.

 i3 : G = momentGraph Gr24 o3 = a "moment graph" on 6 vertices with 12 edges o3 : MomentGraph i4 : underlyingGraph G o4 = Graph{{set {0, 1}} => {{set {0, 2}}, {set {0, 3}}, {set {1, 2}}, {set {1, 3}}}} {set {0, 2}} => {{set {0, 1}}, {set {0, 3}}, {set {1, 2}}, {set {2, 3}}} {set {0, 3}} => {{set {0, 1}}, {set {0, 2}}, {set {1, 3}}, {set {2, 3}}} {set {1, 2}} => {{set {0, 1}}, {set {0, 2}}, {set {1, 3}}, {set {2, 3}}} {set {1, 3}} => {{set {0, 1}}, {set {0, 3}}, {set {1, 2}}, {set {2, 3}}} {set {2, 3}} => {{set {0, 2}}, {set {0, 3}}, {set {1, 2}}, {set {1, 3}}} o4 : Graph

The line bundle $O(1)$ on $Gr(2,4)$, corresponding to its Plücker embedding, can be accessed by ampleKClass(GKMVariety). The method euler(KClass) computes its Lefschetz trace (a.k.a. equivariant Euler characteristic), which in this case is the Laurent polynomial in the character ring of the torus $T$ whose terms correspond to be weights of the second exterior power of the standard representation of $GL_4$.

 i5 : O1 = ampleKClass Gr24 --the O(1) bundle on Gr24 via its Plücker embedding o5 = an "equivariant K-class" on a GKM variety o5 : KClass i6 : euler O1 o6 = T T + T T + T T + T T + T T + T T 0 1 0 2 0 3 1 2 1 3 2 3 o6 : ZZ[T ..T ] 0 3

If $Gr(2,4)$ is embedded differently, say by the line bundle $O(2)$ instead, the Lefschetz trace changes accordingly, and its coefficients record the multiplicities of the associated weight spaces in the second symmetric power of the second exterior power of the standard representation of $GL_4$.

 i7 : euler (O1^2) 2 2 2 2 2 2 2 2 2 2 2 2 o7 = T T + T T T + T T T + T T + T T T + T T + T T T + T T T + T T T 0 1 0 1 2 0 1 3 0 2 0 2 3 0 3 0 1 2 0 1 3 0 1 2 ------------------------------------------------------------------------ 2 2 2 2 2 2 2 2 2 + 2T T T T + T T T + T T T + T T T + T T + T T T + T T + T T T + 0 1 2 3 0 1 3 0 2 3 0 2 3 1 2 1 2 3 1 3 1 2 3 ------------------------------------------------------------------------ 2 2 2 T T T + T T 1 2 3 2 3 o7 : ZZ[T ..T ] 0 3

The Schubert decomposition of $Gr(2,4)$, and more generally the Bruhat decomposition of $G/P$, can be accessed by the method bruhatOrder(GKMVariety), which outputs the poset of the Bruhat order. Moreover, the Schubert varieties can be created via the method generalizedSchubertVariety.

 i8 : P1 = bruhatOrder Gr24 o8 = P1 o8 : Poset i9 : Sch = generalizedSchubertVariety(Gr24,{set{1,2}}) o9 = a "GKM variety" with an action of a 4-dimensional torus o9 : GKMVariety i10 : P2 = bruhatOrder Sch o10 = P2 o10 : Poset

The "forgetful" map from the complete flag variety $Fl(4)$ to $Gr(2,4)$, given by forgetting the subpsaces in the complete flag except for the 2-dimensional one, can be created as a EquivariantMap by the method flagMap.

 i11 : Fl4 = generalizedFlagVariety("A",3,{1,2,3},Gr24.characterRing) --Fl(4) with the torus having the same character ring as Gr24 o11 = a "GKM variety" with an action of a 4-dimensional torus o11 : GKMVariety i12 : f = flagMap(Fl4,Gr24) o12 = an "equivariant map" of GKM varieties o12 : EquivariantMap i13 : Fl4 === f.source and Gr24 === f.target o13 = true

As $Fl(4)$ is a $BiProj$ of vector bundles on $Gr(2,4)$, the (derived) pushforward of the structure sheaf of $Fl(4)$ is the structure sheaf of $Gr(2,4)$ since the higher direct images vanish under the forgetful map.

 i14 : (trivialKClass Gr24) === (pushforward f)(trivialKClass Fl4) o14 = true

For type $C$, the following example features the isotropic Grassmannian $SpGr(2,6)$ consisting of 2-dimensional subspaces in $\mathbb C^6$ that are isotropic with respect to the standard alternating form. The vertices of its moment graph can be considered as the vertices of the cuboctahedron.

 i15 : SpGr26 = generalizedFlagVariety("C",3,{2}) o15 = a "GKM variety" with an action of a 3-dimensional torus o15 : GKMVariety i16 : peek SpGr26 o16 = GKMVariety{cache => CacheTable{...2...} } characterRing => ZZ[T ..T ] 0 2 charts => HashTable{{set {0*, 1*}} => {{1, 0, 1}, {1, 0, -1}, {0, 1, 1}, {0, 1, -1}, {1, 1, 0}, {2, 0, 0}, {0, 2, 0}} } {set {0*, 1}} => {{1, 0, 1}, {1, 0, -1}, {0, -1, 1}, {0, -1, -1}, {2, 0, 0}, {1, -1, 0}, {0, -2, 0}} {set {0*, 2*}} => {{1, 1, 0}, {1, -1, 0}, {1, 0, 1}, {2, 0, 0}, {0, 0, 2}, {0, 1, 1}, {0, -1, 1}} {set {0*, 2}} => {{1, 1, 0}, {1, -1, 0}, {2, 0, 0}, {1, 0, -1}, {0, 0, -2}, {0, 1, -1}, {0, -1, -1}} {set {0, 1*}} => {{-1, 0, 1}, {-1, 0, -1}, {0, 1, 1}, {0, 1, -1}, {0, 2, 0}, {-1, 1, 0}, {-2, 0, 0}} {set {0, 1}} => {{-1, 0, 1}, {-1, 0, -1}, {0, -1, 1}, {0, -1, -1}, {0, -2, 0}, {-2, 0, 0}, {-1, -1, 0}} {set {0, 2*}} => {{-1, 1, 0}, {-1, -1, 0}, {0, 0, 2}, {-1, 0, 1}, {-2, 0, 0}, {0, 1, 1}, {0, -1, 1}} {set {0, 2}} => {{-1, 1, 0}, {-1, -1, 0}, {0, 0, -2}, {-2, 0, 0}, {-1, 0, -1}, {0, 1, -1}, {0, -1, -1}} {set {1*, 2*}} => {{0, 1, 1}, {0, 2, 0}, {0, 0, 2}, {1, 1, 0}, {-1, 1, 0}, {1, 0, 1}, {-1, 0, 1}} {set {1*, 2}} => {{0, 2, 0}, {0, 1, -1}, {0, 0, -2}, {1, 1, 0}, {-1, 1, 0}, {1, 0, -1}, {-1, 0, -1}} {set {1, 2*}} => {{0, 0, 2}, {0, -1, 1}, {0, -2, 0}, {1, -1, 0}, {-1, -1, 0}, {1, 0, 1}, {-1, 0, 1}} {set {1, 2}} => {{0, 0, -2}, {0, -2, 0}, {0, -1, -1}, {1, -1, 0}, {-1, -1, 0}, {1, 0, -1}, {-1, 0, -1}} momentGraph => a "moment graph" on 12 vertices with 42 edges points => {{set {1, 2}}, {set {1, 2*}}, {set {1*, 2}}, {set {1*, 2*}}, {set {0, 2}}, {set {0, 2*}}, {set {0*, 2}}, {set {0*, 2*}}, {set {0, 1}}, {set {0, 1*}}, {set {0*, 1}}, {set {0*, 1*}}} i17 : momentGraph SpGr26 o17 = a "moment graph" on 12 vertices with 42 edges o17 : MomentGraph

The second fundamental representation of $Sp_{6}$ is 14-dimensional with 12 extremal weights.

 i18 : euler ampleKClass SpGr26 -1 -1 -1 -1 -1 -1 o18 = T T + T T + T T + T T + T T + T T + 2 + T T + T T + T T 0 1 0 2 1 2 0 2 0 1 1 2 1 2 0 1 0 2 ----------------------------------------------------------------------- -1 -1 -1 -1 -1 -1 + T T + T T + T T 1 2 0 2 0 1 o18 : ZZ[T ..T ] 0 2

For type $B$, the following example features the isotropic Grassmannian $SOGr(2,5)$ consisting of 3-dimensional subspaces in $\mathbb C^5$ that are isotropic with respect to the standard symmetric form. Its moment graph is the a complete graph on 4 vertices. Note that Spin groups and their representations are not implemented, so for the type $B_n$ the coefficient $a_n$ need be a multiple of 2.

 i19 : SOGr25 = generalizedFlagVariety("B",2,{2,2}) --inputing {2} instead of {2,2} results in error: spin groups not implemented yet o19 = a "GKM variety" with an action of a 2-dimensional torus o19 : GKMVariety i20 : peek SOGr25 o20 = GKMVariety{cache => CacheTable{...2...} } characterRing => ZZ[T ..T ] 0 1 charts => HashTable{{set {0*, 1*}} => {{1, 1}, {1, 0}, {0, 1}} } {set {0*, 1}} => {{1, 0}, {1, -1}, {0, -1}} {set {0, 1*}} => {{0, 1}, {-1, 1}, {-1, 0}} {set {0, 1}} => {{0, -1}, {-1, 0}, {-1, -1}} momentGraph => a "moment graph" on 4 vertices with 6 edges points => {{set {0, 1}}, {set {0, 1*}}, {set {0*, 1}}, {set {0*, 1*}}} i21 : euler ampleKClass SOGr25 -1 -1 -1 -1 -1 -1 o21 = T T + T + T + T T + 2 + T T + T + T + T T 0 1 0 1 0 1 0 1 1 0 0 1 o21 : ZZ[T ..T ] 0 1

For type $D$, the following example features the isotropic Grassmannian $SOGr(3,8)$ consisting of 3-dimensional subspaces in $\mathbb C^8$ that are isotropic with respect to the standard symmetric form.

 i22 : SOGr38 = generalizedFlagVariety("D",4,{3,4}) o22 = a "GKM variety" with an action of a 4-dimensional torus o22 : GKMVariety i23 : SOGr38.points o23 = {{set {1, 2, 3}}, {set {1, 2, 3*}}, {set {1, 2*, 3}}, {set {1, 2*, ----------------------------------------------------------------------- 3*}}, {set {1*, 2, 3}}, {set {1*, 2, 3*}}, {set {1*, 2*, 3}}, {set {1*, ----------------------------------------------------------------------- 2*, 3*}}, {set {0, 2, 3}}, {set {0, 2, 3*}}, {set {0, 2*, 3}}, {set {0, ----------------------------------------------------------------------- 2*, 3*}}, {set {0*, 2, 3}}, {set {0*, 2, 3*}}, {set {0*, 2*, 3}}, {set ----------------------------------------------------------------------- {0*, 2*, 3*}}, {set {0, 1, 3}}, {set {0, 1, 3*}}, {set {0, 1*, 3}}, ----------------------------------------------------------------------- {set {0, 1*, 3*}}, {set {0*, 1, 3}}, {set {0*, 1, 3*}}, {set {0*, 1*, ----------------------------------------------------------------------- 3}}, {set {0*, 1*, 3*}}, {set {0, 1, 2}}, {set {0, 1, 2*}}, {set {0, ----------------------------------------------------------------------- 1*, 2}}, {set {0, 1*, 2*}}, {set {0*, 1, 2}}, {set {0*, 1, 2*}}, {set ----------------------------------------------------------------------- {0*, 1*, 2}}, {set {0*, 1*, 2*}}} o23 : List

Similarly as in type $B$, Spin groups are not implemented, so the two connected components of $SOGr(4,8)$ need be separatedly created in the following way.

 i24 : SOGr48odd = generalizedFlagVariety("D",4,{3,3}) o24 = a "GKM variety" with an action of a 4-dimensional torus o24 : GKMVariety i25 : SOGr48odd.points o25 = {{set {0*, 1, 2, 3}}, {set {0*, 1, 2*, 3*}}, {set {0*, 1*, 2, 3*}}, ----------------------------------------------------------------------- {set {0*, 1*, 2*, 3}}, {set {0, 1, 2, 3*}}, {set {0, 1, 2*, 3}}, {set ----------------------------------------------------------------------- {0, 1*, 2, 3}}, {set {0, 1*, 2*, 3*}}} o25 : List i26 : SOGr48even = generalizedFlagVariety("D",4,{4,4}) o26 = a "GKM variety" with an action of a 4-dimensional torus o26 : GKMVariety i27 : SOGr48even.points o27 = {{set {0, 1, 2, 3}}, {set {0, 1, 2*, 3*}}, {set {0, 1*, 2, 3*}}, {set ----------------------------------------------------------------------- {0, 1*, 2*, 3}}, {set {0*, 1, 2, 3*}}, {set {0*, 1, 2*, 3}}, {set {0*, ----------------------------------------------------------------------- 1*, 2, 3}}, {set {0*, 1*, 2*, 3*}}} o27 : List

## Caveat

Does not check for low-dimensional isogenies. For instance, always use type $D_n$ with $n\geq 4$ to be safe.