# character(ActionOnComplex,ZZ) -- compute Betti characters of minimal free resolution

## Synopsis

• Function: character
• Usage:
character(A,i)
• Inputs:
• A, an instance of the type ActionOnComplex, a finite group action on a minimal free resolution
• i, an integer, a homological degree
• Outputs:
• an instance of the type Character, the i-th Betti character of the resolution

## Description

This function is provided by the package BettiCharacters.

Use this function to compute the Betti characters of a finite group action on a minimal free resolution in a given homological degree. More explicitly, let $F_\bullet$ be a minimal free resolution of a module $M$ over a polynomial ring $R$, with a compatible action of a finite group $G$. If $\mathfrak{m}$ denotes the maximal ideal generated by the variables of $R$, then $F_i/\mathfrak{m}F_i$ is a graded representation of $G$. We refer to its character as the $i$-th Betti character of $M$ (or a minimal free resolution of $M$). Betti characters are computed using Algorithm 1 in F. Galetto - Finite group characters on free resolutions.

To illustrate, we compute the Betti characters of a symmetric group on the resolution of a monomial ideal. The ideal is the symbolic square of the ideal generated by all squarefree monomials of degree three in four variables. The symmetric group acts by permuting the four variables of the ring. The characters are determined by five permutations with cycle types, in order: 4, 31, 22, 211, 1111.

 i1 : R = QQ[x_1..x_4] o1 = R o1 : PolynomialRing i2 : J = intersect(apply(subsets(gens R,3),x->(ideal x)^2)) 2 2 2 2 2 2 2 2 2 2 o2 = ideal (x x x , x x x , x x x , x x x , x x , x x , x x , x x , x x , 2 3 4 1 3 4 1 2 4 1 2 3 3 4 2 4 1 4 2 3 1 3 ------------------------------------------------------------------------ 2 2 x x ) 1 2 o2 : Ideal of R i3 : RJ = res J 1 10 15 6 o3 = R <-- R <-- R <-- R <-- 0 0 1 2 3 4 o3 : ChainComplex i4 : G = { matrix{{x_2,x_3,x_4,x_1}}, matrix{{x_2,x_3,x_1,x_4}}, matrix{{x_2,x_1,x_4,x_3}}, matrix{{x_2,x_1,x_3,x_4}}, matrix{{x_1,x_2,x_3,x_4}} } o4 = {| x_2 x_3 x_4 x_1 |, | x_2 x_3 x_1 x_4 |, | x_2 x_1 x_4 x_3 |, | x_2 ------------------------------------------------------------------------ x_1 x_3 x_4 |, | x_1 x_2 x_3 x_4 |} o4 : List i5 : A = action(RJ,G) o5 = ChainComplex with 5 actors o5 : ActionOnComplex i6 : character(A,0) o6 = Character over R (0, {0}) => | 1 1 1 1 1 | o6 : Character

By construction, the character in homological degree 0 is concentrated in degree 0 and trivial.

 i7 : character(A,1) o7 = Character over R (1, {3}) => | 0 1 0 2 4 | (1, {4}) => | 0 0 2 2 6 | o7 : Character

The character in homological degree 1 has two components. The component of degree 3 is the permutation representation spanned by the squarefree monomials of degree 3 (which can be identified with the natural representation of the symmetric group). The component of degree 4 is the permutation representation spanned by the squares of the squarefree monomials of degree 2.

 i8 : character(A,2) o8 = Character over R (2, {4}) => | -1 0 -1 1 3 | (2, {5}) => | 0 0 0 2 12 | o8 : Character

In homological degree 2, there is a component of degree 4 which is isomorphic to the irreducible standard representation of the symmetric group. In degree 5, we find the permutation representation of the symmetric group on the set of ordered pairs of distinct elements from 1 to 4.

 i9 : character(A,3) o9 = Character over R (3, {6}) => | 0 0 -2 0 6 | o9 : Character

Finally, the character in homological degree 3 is concentrated in degree 6 and corresponds to the direct sum of the standard representation and the tensor product of the standard representation and the sign representation (i.e., the direct sum of the two irreducible representations of dimension 3).