next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Macaulay2Doc > basic commutative algebra > M2SingularBook > Singular Book 1.8.13

Singular Book 1.8.13 -- quotient of ideals

i1 : A = QQ[x,y,z];
i2 : I1 = ideal(x,y);

o2 : Ideal of A
i3 : I2 = ideal(y^2,z);

o3 : Ideal of A
i4 : I1 : I2

o4 = ideal (y, x)

o4 : Ideal of A
The quotient function is the same as the colon operator, except that optional arguments may be given.
i5 : quotient(I1,I2)

o5 = ideal (y, x)

o5 : Ideal of A
Now we use the method described in Lemma 1.8.12 in the Singular book.
i6 : J1 = intersect(I1,ideal(I2_0))

            2
o6 = ideal y

o6 : Ideal of A
i7 : J2 = intersect(I1,ideal(I2_1))

o7 = ideal (y*z, x*z)

o7 : Ideal of A
Now divide each generator of J1 by x, and each generator of J2 by y. Notice that division uses two slashes. Using only one slash gives the quotient in the fraction ring.
i8 : K1 = ideal(J1_0//I2_0)

o8 = ideal 1

o8 : Ideal of A
i9 : K2 = ideal(J2_0//I2_1, J2_1//I2_1)

o9 = ideal (y, x)

o9 : Ideal of A
i10 : intersect(K1,K2)

o10 = ideal (y, x)

o10 : Ideal of A