adjoint(Matrix,Module,Module) -- an adjoint map

Synopsis

• Function: adjoint

• Usage:

  adjoint(f,F,G)

• Inputs:
  • f, a matrix, a homomorphism F ** G --> H
  • F, a module, a free module
  • G, a module, a free module
• Outputs:
  • a matrix, the adjoint homomorphism F --> Hom(G,H)

Description

Recall that ** refers to the tensor product of modules.

i1 : R = QQ[x_1 .. x_24];

i2 : f = genericMatrix(R,2,4*3)

o2 = | x_1 x_3 x_5 x_7 x_9  x_11 x_13 x_15 x_17 x_19 x_21 x_23 |
     | x_2 x_4 x_6 x_8 x_10 x_12 x_14 x_16 x_18 x_20 x_22 x_24 |

             2       12
o2 : Matrix R  <--- R

i3 : isHomogeneous f

o3 = true

i4 : g = adjoint(f,R^4,R^3)

o4 = | x_1 x_7  x_13 x_19 |
     | x_2 x_8  x_14 x_20 |
     | x_3 x_9  x_15 x_21 |
     | x_4 x_10 x_16 x_22 |
     | x_5 x_11 x_17 x_23 |
     | x_6 x_12 x_18 x_24 |

             6       4
o4 : Matrix R  <--- R

If f is homogeneous, and source f === F ** G (including the grading), then the resulting matrix will be homogeneous.

i5 : g = adjoint(f,R^4,R^{-1,-1,-1})

o5 = {-1} | x_1 x_7  x_13 x_19 |
     {-1} | x_2 x_8  x_14 x_20 |
     {-1} | x_3 x_9  x_15 x_21 |
     {-1} | x_4 x_10 x_16 x_22 |
     {-1} | x_5 x_11 x_17 x_23 |
     {-1} | x_6 x_12 x_18 x_24 |

             6       4
o5 : Matrix R  <--- R

i6 : isHomogeneous g

o6 = true

See also

• adjoint' -- an adjoint map
• flip -- matrix of commutativity of tensor product
• reshape -- reshape a matrix
• Module ** Module -- tensor product
• dual -- dual module or map