# Example 5 -- The singular locus of a symplectic invariant

Consider the symplectic group $Sp(6,{\mathbb C})$ of type $C_3$. We denote $V(\omega)$ the highest weight representation of $Sp(6,{\mathbb C})$ with highest weight $\omega$. We denote by $\omega_1,...,\omega_3$ the fundamental weights in the root system of type $C_3$.

The action of $Sp(6,{\mathbb C})$ on $V(\omega_3)$, the third fundamental representation, has a unique invariant $\Delta$ of degree 4. If we regard $V(\omega_3)$ as a complex affine space, $\Delta$ describes a hypersurface. We will determine and decompose the minimal free resolution of the coordinate ring of the singular locus of this hypersurface. This singular locus is one of the four orbit closures for the action of $Sp(6,{\mathbb C})$ on $V(\omega_3)$ and has been studied, for example, in Galetto - Free resolutions of orbit closures for the representations associated to gradings on Lie algebras of type E6, F4 and G2. A concise description of this singular locus, together with a construction of the representation $V(\omega_3)$, was also given in Iliev, Ranestad - Geometry of the Lagrangian Grassmannian LG(3,6) with Applications to Brill–Noether Loci. We will follow the notation of this second source.

The standard representation $V=V(\omega_1)$ of $Sp(6,{\mathbb C})$ is a six dimensional complex vector space endowed with a symplectic form. Being a symplectic space, $V$ is self dual. Let $x_1,...,x_6$ be a basis for the coordinate functions on $V$. The symplectic form on $V$ can be written as $x_1\wedge x_4 +x_3\wedge x_5 +x_3\wedge x_6 \in \wedge^2 V^*$. The wedge product with this form induces a map $V^* \to \wedge^3 V^*$ whose cokernel is the representation $V(\omega_3)$. As such, the residue classes $x_{i,j,k}$ of the tensors $x_i\wedge x_j\wedge x_k$ span $V(\omega_3)$. Since $V(\omega_3)$ is self dual, we can take the $x_{i,j,k}$ to span the coordinate functions on $V(\omega_3)$. Finally, some of the $x_{i,j,k}$ can be omitted and the remaining ones will be variables in our polynomial ring $R$.

 i1 : R=QQ[x_{1,2,3},x_{1,2,4},x_{1,2,5},x_{1,2,6},x_{1,3,4},x_{1,3,5},x_{1,4,5},x_{1,4,6},x_{1,5,6},x_{2,3,4},x_{2,4,5},x_{2,4,6},x_{3,4,5},x_{4,5,6}] o1 = R o1 : PolynomialRing

The invariant $\Delta$ can be written in terms of certain matrices of variables, as indicated in our source.

 i2 : X=matrix{{x_{2,3,4},-x_{1,3,4},x_{1,2,4}},{-x_{1,3,4},-x_{1,3,5},x_{1,2,5}},{x_{1,2,4},x_{1,2,5},x_{1,2,6}}} o2 = | x_{2, 3, 4} -x_{1, 3, 4} x_{1, 2, 4} | | -x_{1, 3, 4} -x_{1, 3, 5} x_{1, 2, 5} | | x_{1, 2, 4} x_{1, 2, 5} x_{1, 2, 6} | 3 3 o2 : Matrix R <--- R i3 : Y=matrix{{x_{1,5,6},-x_{1,4,6},x_{1,4,5}},{-x_{1,4,6},-x_{2,4,6},x_{2,4,5}},{x_{1,4,5},x_{2,4,5},x_{3,4,5}}} o3 = | x_{1, 5, 6} -x_{1, 4, 6} x_{1, 4, 5} | | -x_{1, 4, 6} -x_{2, 4, 6} x_{2, 4, 5} | | x_{1, 4, 5} x_{2, 4, 5} x_{3, 4, 5} | 3 3 o3 : Matrix R <--- R i4 : Delta=(x_{1,2,3}*x_{4,5,6}-trace(X*Y))^2+4*x_{1,2,3}*det(Y)+4*x_{4,5,6}*det(X)-4*sum(3,i->sum(3,j->det(submatrix'(X,{i},{j}))*det(submatrix'(Y,{i},{j}))));

The equations of the singular locus of the hypersurface cut out by $\Delta$ are the partial derivatives of $\Delta$. Let us calculate the resolution of this ideal.

 i5 : I=ideal jacobian ideal Delta; o5 : Ideal of R i6 : RI=res I; betti RI 0 1 2 3 4 o7 = total: 1 14 21 14 6 0: 1 . . . . 1: . . . . . 2: . 14 21 . . 3: . . . 14 6 o7 : BettiTally

The root system of type $C_3$ is contained in $\RR^3$. It is easy to express the weight of each variable of the ring $R$ with respect to the coordinate basis of $\RR^3$. The weight of $x_{i,j,k}$ is the vector $v_i+v_j+v_k$, where $v_h$ is the weight of $x_h$ in the coordinate basis of $\RR^3$.

 i8 : v_1={1,0,0}; v_2={0,1,0}; v_3={0,0,1}; v_4={-1,0,0}; v_5={0,-1,0}; v_6={0,0,-1}; i14 : ind = apply(gens R,g->(baseName g)#1) o14 = {{1, 2, 3}, {1, 2, 4}, {1, 2, 5}, {1, 2, 6}, {1, 3, 4}, {1, 3, 5}, {1, ----------------------------------------------------------------------- 4, 5}, {1, 4, 6}, {1, 5, 6}, {2, 3, 4}, {2, 4, 5}, {2, 4, 6}, {3, 4, ----------------------------------------------------------------------- 5}, {4, 5, 6}} o14 : List i15 : W'=apply(ind,j->v_(j_0)+v_(j_1)+v_(j_2)) o15 = {{1, 1, 1}, {0, 1, 0}, {1, 0, 0}, {1, 1, -1}, {0, 0, 1}, {1, -1, 1}, ----------------------------------------------------------------------- {0, -1, 0}, {0, 0, -1}, {1, -1, -1}, {-1, 1, 1}, {-1, 0, 0}, {-1, 1, ----------------------------------------------------------------------- -1}, {-1, -1, 1}, {-1, -1, -1}} o15 : List

Now we convert these weights into the basis of fundamental weights. To achieve this we make each previous weight into a column vector and join all column vectors into a matrix. Then we multiply on the left by the matrix $M$ expressing the change of basis from the coordinate basis of $\RR^3$ to the base of simple roots of $C_3$ (as described in Humphreys - Introduction to Lie Algebras and Representation Theory, Ch. 12.1). Finally we multiply the resulting matrix on the left by $N$, the transpose of the Cartan matrix of $C_3$, which expresses the change of basis from the simple roots to the fundamental weights of $C_3$. The columns of the matrix thus obtained are the desired weights, so they can be attached to the ring $R$.

 i16 : M=inverse promote(matrix{{1,0,0},{-1,1,0},{0,-1,2}},QQ) o16 = | 1 0 0 | | 1 1 0 | | 1/2 1/2 1/2 | 3 3 o16 : Matrix QQ <--- QQ i17 : D=dynkinType{{"C",3}} o17 = DynkinType{{C, 3}} o17 : DynkinType i18 : N=transpose promote(cartanMatrix(rootSystem(D)),QQ) o18 = | 2 -1 0 | | -1 2 -2 | | 0 -1 2 | 3 3 o18 : Matrix QQ <--- QQ i19 : W=entries transpose lift(N*M*(transpose matrix W'),ZZ) o19 = {{0, 0, 1}, {-1, 1, 0}, {1, 0, 0}, {0, 2, -1}, {0, -1, 1}, {2, -2, 1}, ----------------------------------------------------------------------- {1, -1, 0}, {0, 1, -1}, {2, 0, -1}, {-2, 0, 1}, {-1, 0, 0}, {-2, 2, ----------------------------------------------------------------------- -1}, {0, -2, 1}, {0, 0, -1}} o19 : List i20 : setWeights(R,D,W) o20 = Tally{{0, 0, 1} => 1} o20 : Tally

At this stage, we can issue the command to decompose the resolution.

 i21 : highestWeightsDecomposition(RI) o21 = HashTable{0 => HashTable{{0} => Tally{{0, 0, 0} => 1}}} 1 => HashTable{{3} => Tally{{0, 0, 1} => 1}} 2 => HashTable{{4} => Tally{{2, 0, 0} => 1}} 3 => HashTable{{6} => Tally{{0, 1, 0} => 1}} 4 => HashTable{{7} => Tally{{1, 0, 0} => 1}} o21 : HashTable

We deduce that the resolution has the following structure $$R \leftarrow V(\omega_3) \otimes R(-3) \leftarrow V(2\omega_1) \otimes R(-4) \leftarrow V(\omega_2) \otimes R(-6) \leftarrow V(\omega_1) \otimes R(-7) \leftarrow 0$$

Let us also decompose some graded components of the quotient $R/I$.

 i22 : highestWeightsDecomposition(R/I,0,4) o22 = HashTable{0 => Tally{{0, 0, 0} => 1}} 1 => Tally{{0, 0, 1} => 1} 2 => Tally{{0, 0, 2} => 1} {2, 0, 0} => 1 3 => Tally{{0, 0, 3} => 1} {2, 0, 1} => 1 4 => Tally{{0, 0, 4} => 1} {2, 0, 2} => 1 {4, 0, 0} => 1 o22 : HashTable