next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Complexes :: part(List,Complex)

part(List,Complex) -- extract a graded component of a complex

Synopsis

Description

If $C$ is a graded (homogeneous) complex over a ring $R$, and $d$ is a degree, this method computes the degree $d$ part of the complex over the coefficient ring of $R$.

Taking parts of a graded (homogeneous) complex commutes with taking homology.

i1 : R = QQ[a,b,c,d];
i2 : I = ideal(a*b, a*c, b*c, a*d)

o2 = ideal (a*b, a*c, b*c, a*d)

o2 : Ideal of R
i3 : C = freeResolution I

      1      4      4      1
o3 = R  <-- R  <-- R  <-- R
                           
     0      1      2      3

o3 : Complex
i4 : D = part(4,C)

       35       40       16       1
o4 = QQ   <-- QQ   <-- QQ   <-- QQ
                                 
     0        1        2        3

o4 : Complex
i5 : prune HH D == part(4, HH C)

o5 = true
i6 : prune HH D == part(4, complex(R^1/I))

o6 = true

Given a squarefree monomial ideal corresponding to a simplicial complex, in a polynomial ring equipped with the fine grading, parts of the dual of the free resolution of the monomial ideal are the chain complexes of the induced simplicial subcomplexes.

i7 : S = QQ[a..d, DegreeRank=>4];
i8 : I = intersect(ideal(a,b), ideal(c,d))

o8 = ideal (b*d, a*d, b*c, a*c)

o8 : Ideal of S
i9 : C = dual freeResolution I

      1      4      4      1
o9 = S  <-- S  <-- S  <-- S
                           
     -3     -2     -1     0

o9 : Complex
i10 : prune HH (part({-1,-1,-1,-1}, C)) -- empty quadrilateral

        1
o10 = QQ
       
      -3

o10 : Complex
i11 : prune HH part({-1,-1,0,0}, C) -- 2 points

        1
o11 = QQ
       
      -2

o11 : Complex
i12 : prune HH part({0,0,-1,-1}, C) -- 2 points

        1
o12 = QQ
       
      -2

o12 : Complex
i13 : prune HH part({0,0,0,0}, C) -- solid quadrilateral

o13 = 0
       
      0

o13 : Complex

See also