next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Quasidegrees :: quasidegrees

quasidegrees -- compute the quasidegree set of a module

Synopsis

Description

The method quasidegrees takes a finitely generated module $M$ over the polynomial ring that is presented by a monomial matrix and computes the quasidegree set of $M$. The quasidegrees of $M$ are indexed by a list of pairs $(v,F)$ where $v$ is a vector and $F$ is a list of vectors f1,...,fl. The pair $(v,F)$ indexes the plane $v+span_\CCF$. The quasidegree set of M is the union of all such planes that the pairs (v,F) index.

If the input is an ideal $I$, then quasidegrees executes for the module $R/I$ where $R$ is the ring of $I$.

The following example computes the quasidegree set of $\QQ[x,y]/<x^2,y^2>$ under the standard $\ZZ^2$-grading.

i1 : A = matrix{{1,0},{0,1}}

o1 = | 1 0 |
     | 0 1 |

              2        2
o1 : Matrix ZZ  <--- ZZ
i2 : R = QQ[x,y, Degrees => entries transpose A]

o2 = R

o2 : PolynomialRing
i3 : I = ideal(x^2,y^2)

             2   2
o3 = ideal (x , y )

o3 : Ideal of R
i4 : M = R^1/I

o4 = cokernel | x2 y2 |

                            1
o4 : R-module, quotient of R
i5 : quasidegrees M

o5 = {{0, {}}, {| 0 |, {}}, {| 1 |, {}}, {| 1 |, {}}}
                | 1 |        | 0 |        | 1 |

o5 : List

The quasidegree set is given to be the points (0,1), (1,0), (1,1), and (0,0).

The next example takes $R$ computes the quasidegrees of the above module after twisting $R$ by multidegree (3,2).

i6 : R = R^{{-3,-2}}

               1
o6 = (QQ[x..y])

o6 : QQ[x..y]-module, free, degrees {{3, 2}}
i7 : M = R^1/I

o7 = cokernel {3, 2} | x2 y2 |

                                            1
o7 : QQ[x..y]-module, quotient of (QQ[x..y])
i8 : quasidegrees M

o8 = {{| 4 |, {}}, {| 4 |, {}}, {| 3 |, {}}, {| 3 |, {}}}
       | 2 |        | 3 |        | 3 |        | 2 |

o8 : List

The following demonstrates a quasidegree set that is not a finite number of points.

i9 : A = matrix{{1,0},{0,1}}

o9 = | 1 0 |
     | 0 1 |

              2        2
o9 : Matrix ZZ  <--- ZZ
i10 : R = QQ[x,y]

o10 = R

o10 : PolynomialRing
i11 : R = toGradedRing(A,R)

o11 = R

o11 : PolynomialRing
i12 : I = ideal(x^2*y,y^2)

              2    2
o12 = ideal (x y, y )

o12 : Ideal of R
i13 : M=R^1/I

o13 = cokernel | x2y y2 |

                             1
o13 : R-module, quotient of R
i14 : quasidegrees M

o14 = {{| 1 |, {}}, {| 0 |, {}}, {0, {| 1 |}}}
        | 1 |        | 1 |            | 0 |

o14 : List

In the above example, the quasidegree set of the module M consists of the points (1,1) and (0,1) along with the parameterized line (1,0)$\bullet t$.

Ways to use quasidegrees :

For the programmer

The object quasidegrees is a method function.