next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: weilDivisorGroup(ToricMap)

weilDivisorGroup(ToricMap) -- make the induced map between groups of Weil divisors

Synopsis

Description

Given a toric map $f : X \to Y$ where $Y$ a smooth toric variety, this method returns the induced map of abelian groups from the group of torus-invariant Weil divisors on $Y$ to the group of torus-invariant Weil divisors on $X$. For arbitrary normal toric varieties, the weilDivisorGroup is not a functor. However, weilDivisorGroup is a contravariant functor on the category of smooth normal toric varieties.

We illustrate this method on the projection from the first Hirzebruch surface to the projective line.

i1 : X = hirzebruchSurface 1;
i2 : Y = toricProjectiveSpace 1;
i3 : f = map(Y, X, matrix {{1, 0}})

o3 = | 1 0 |

o3 : ToricMap Y <--- X
i4 : f' = weilDivisorGroup f

o4 = | 0 1 |
     | 0 0 |
     | 1 0 |
     | 0 0 |

              4        2
o4 : Matrix ZZ  <--- ZZ
i5 : assert (isWellDefined f and source f' == weilDivisorGroup Y and
         target f' == weilDivisorGroup X)

The next example gives the induced map from the group of torus-invariant Weil divisors on the projective plane to the group of torus-invariant Weil divisors on the first Hirzebruch surface.

i6 : Z = toricProjectiveSpace 2;
i7 : g = map(Z, X, matrix {{1, 0}, {0, -1}})

o7 = | 1 0  |
     | 0 -1 |

o7 : ToricMap Z <--- X
i8 : g' = weilDivisorGroup g

o8 = | 0 1 0 |
     | 1 1 0 |
     | 1 0 0 |
     | 0 0 1 |

              4        3
o8 : Matrix ZZ  <--- ZZ
i9 : assert (isWellDefined g and source g' == weilDivisorGroup Z and
         target g' == weilDivisorGroup X)

The induced map between the groups of torus-invariant Weil divisors is compatible with the induced map between the class groups.

i10 : g'' = classGroup g

o10 = | 0 |
      | 1 |

               2        1
o10 : Matrix ZZ  <--- ZZ
i11 : assert(g'' * fromWDivToCl Z  == fromWDivToCl X  * g')

See also