next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: todd(CoherentSheaf)

todd(CoherentSheaf) -- compute the Todd class of a coherent sheaf

Synopsis

Description

Given a locally-free sheaf $E$ of rank $r$ on a smooth variety such that its Chern class formally factor as chern $E = \prod_{j=1}^r (1 + \alpha_j)$, we define its Todd class to be todd $E := \prod_{j=1}^r \alpha_j / [1- exp(-\alpha_j)]$ written as a polynomial in the elementary symmetric functions chern $(i, E)$ of the $\alpha_j$.

The first few components of the Todd class are easily related to Chern classes.

i1 : X0 = kleinschmidt(4, {1,3,5});
i2 : E0 = cotangentSheaf X0

o2 = cokernel {2, 0}  | 2x_2x_3 4x_1x_3 5x_0x_3 0     0    2x_1x_2 0     0    0     0     3x_0x_2 0     0     0     0     x_0x_1 0     0     0     0     0     0     0    0     |
              {-7, 2} | x_4     0       0       0     x_1  0       0     0    0     3x_0  0       0     0     0     0     0      0     0     0     0     0     0     0    0     |
              {-7, 2} | -x_5    0       0       0     0    0       0     x_1  0     0     0       0     3x_0  0     0     0      0     0     0     0     0     0     0    0     |
              {-5, 2} | 0       x_4     0       x_2   0    0       0     0    0     0     0       0     0     0     x_0   0      0     0     0     0     0     0     0    0     |
              {-5, 2} | 0       -x_5    0       0     0    0       x_2   0    0     0     0       0     0     0     0     0      0     x_0   0     0     0     0     0    0     |
              {-4, 2} | 0       0       x_4     0     0    0       0     0    3x_2  0     0       0     0     x_1   0     0      0     0     0     0     0     0     0    0     |
              {-4, 2} | 0       0       -x_5    0     0    0       0     0    0     0     0       3x_2  0     0     0     0      x_1   0     0     0     0     0     0    0     |
              {-3, 2} | 0       0       0       -2x_3 -x_3 x_4     0     0    0     0     0       0     0     0     0     0      0     0     0     x_0   0     0     0    0     |
              {-9, 3} | 0       0       0       -x_5  -x_5 0       -x_4  -x_4 0     0     0       0     0     0     0     0      0     0     0     0     0     0     x_0  0     |
              {-3, 2} | 0       0       0       0     0    -x_5    -2x_3 -x_3 0     0     0       0     0     0     0     0      0     0     0     0     0     x_0   0    0     |
              {-2, 2} | 0       0       0       0     0    0       0     0    -5x_3 -2x_3 x_4     0     0     0     0     0      0     0     x_1   0     0     0     0    0     |
              {-8, 3} | 0       0       0       0     0    0       0     0    -x_5  -x_5  0       -x_4  -x_4  0     0     0      0     0     0     0     0     0     0    x_1   |
              {-2, 2} | 0       0       0       0     0    0       0     0    0     0     -x_5    -5x_3 -2x_3 0     0     0      0     0     0     0     x_1   0     0    0     |
              {0, 2}  | 0       0       0       0     0    0       0     0    0     0     0       0     0     -5x_3 -4x_3 x_4    0     0     -3x_2 -2x_2 0     0     0    0     |
              {-6, 3} | 0       0       0       0     0    0       0     0    0     0     0       0     0     -x_5  -x_5  0      -x_4  -x_4  0     0     0     0     -x_2 -3x_2 |
              {0, 2}  | 0       0       0       0     0    0       0     0    0     0     0       0     0     0     0     -x_5   -5x_3 -4x_3 0     0     -3x_2 -2x_2 0    0     |
              {-4, 3} | 0       0       0       0     0    0       0     0    0     0     0       0     0     0     0     0      0     0     -x_5  -x_5  -x_4  -x_4  2x_3 5x_3  |

                                           1                2                2                2                1                1                1                1                1                1                1                1                1                1
o2 : coherent sheaf on X0, quotient of OO    (-2, 0) ++ OO    (7, -2) ++ OO    (5, -2) ++ OO    (4, -2) ++ OO    (3, -2) ++ OO    (9, -3) ++ OO    (3, -2) ++ OO    (2, -2) ++ OO    (8, -3) ++ OO    (2, -2) ++ OO    (0, -2) ++ OO    (6, -3) ++ OO    (0, -2) ++ OO    (4, -3)
                                         X0               X0               X0               X0               X0               X0               X0               X0               X0               X0               X0               X0               X0               X0
i3 : A0 = intersectionRing X0;
i4 : todd E0

                  13       11 2   145            3   121 2       3
o4 = 1 + (- 2t  - --t ) + (--t  + ---t t ) + (- t  - ---t t ) + t t
              3    2 5      6 3    12 3 5        3    12 3 5     3 5

o4 : A0
i5 : assert (part (0, todd E0) == 1)
i6 : assert (part (1, todd E0) === (1/2) * chern (1, E0))
i7 : assert (part (2, todd E0) === (1/12)*((chern (1, E0))^2 + chern (2, E0)))

On a complete smooth normal toric variety, the Todd class of the tangent bundle factors as a product over the irreducible torus-invariant divisors.

i8 : X1 = smoothFanoToricVariety (3, 12);
i9 : E1 = dual cotangentSheaf X1

o9 = image {0, 0, -2, 0} | 0          0          0          x_2          x_3          |
           {0, -2, 0, 0} | 0          -x_6       x_1x_4     0            0            |
           {-2, 0, 0, 0} | -x_3x_6    0          -x_0x_3x_5 x_0x_5x_6    0            |
           {-2, 0, 0, 0} | x_2x_6     0          x_0x_2x_5  0            x_0x_5x_6    |
           {0, 0, 0, -2} | -x_1x_3x_4 -x_0x_3x_5 0          x_0x_1x_4x_5 0            |
           {0, 0, 0, -2} | x_1x_2x_4  x_0x_2x_5  0          0            x_0x_1x_4x_5 |

                                           1                     1                     2                     2
o9 : coherent sheaf on X1, subsheaf of OO    (0, 0, 2, 0) ++ OO    (0, 2, 0, 0) ++ OO    (2, 0, 0, 0) ++ OO    (0, 0, 0, 2)
                                         X1                    X1                    X1                    X1
i10 : A1 = intersectionRing X1;
i11 : f1 = todd E1

           3               1       3        2   2       2 2     3
o11 = 1 + (-t  + t  + t  + -t ) + (-t t  - t  - -t t  - -t ) + t
           2 3    4    5   2 6     2 3 4    5   3 5 6   3 6     6

o11 : A1
i12 : assert (f1 === product(# rays X1, i -> todd OO (X1_i)))

Applying todd to a normal toric variety is the same as applying it to the tangent sheaf of the variety.

See also