next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: smallAmpleToricDivisor(ZZ,ZZ)

smallAmpleToricDivisor(ZZ,ZZ) -- get a very ample toric divisor from the database

Synopsis

Description

This method function accesses a database of equivalence classes of very ample divisors that embed their underlying smooth toric varieties into low-dimensional projective spaces.

The enumeration of the $41$ smooth projective toric surfaces embedding into at most projective $11$-space follows the classification in [Tristram Bogart, Christian Haase, Milena Hering, Benjamin Lorenz, Benjamin Nill Andreas Paffenholz, G√ľnter Rote, Francisco Santos, and Hal Schenck, Finitely many smooth d-polytopes with n lattice points, Israel J. Math., 207 (2015) 301-329].

The enumeration of the $103$ smooth projective toric threefolds embedding into at most projective $15$-space follows [Anders Lundman, A classification of smooth convex 3-polytopes with at most 16 lattice points, J. Algebr. Comb., 37 (2013) 139-165].

The first $2$ toric divisors over a surface lie over a product of projective lines.

i1 : D1 = smallAmpleToricDivisor(2,0)

o1 = 2*D  + 2*D
        1      3

o1 : ToricDivisor on normalToricVariety ({{1, 0}, {-1, 0}, {0, 1}, {0, -1}}, {{0, 2}, {0, 3}, {1, 2}, {1, 3}})
i2 : assert isVeryAmple D1
i3 : X1 = variety D1;
i4 : assert (isSmooth X1 and isProjective X1)
i5 : rays X1

o5 = {{1, 0}, {-1, 0}, {0, 1}, {0, -1}}

o5 : List
i6 : D1

o6 = 2*X1  + 2*X1
         1       3

o6 : ToricDivisor on X1
i7 : latticePoints D1

o7 = | 0 1 2 0 1 2 0 1 2 |
     | 0 0 0 1 1 1 2 2 2 |

              2        9
o7 : Matrix ZZ  <--- ZZ
i8 : D2 = smallAmpleToricDivisor (2,1);

o8 : ToricDivisor on normalToricVariety ({{1, 0}, {-1, 0}, {0, 1}, {0, -1}}, {{0, 2}, {0, 3}, {1, 2}, {1, 3}})
i9 : assert isVeryAmple D2
i10 : X2 = variety D2;
i11 : assert (isSmooth X2 and isProjective X2)
i12 : rays X2

o12 = {{1, 0}, {-1, 0}, {0, 1}, {0, -1}}

o12 : List
i13 : D2

o13 = 3*X2  + 2*X2
          1       3

o13 : ToricDivisor on X2
i14 : latticePoints D2

o14 = | 0 1 2 3 0 1 2 3 0 1 2 3 |
      | 0 0 0 0 1 1 1 1 2 2 2 2 |

               2        12
o14 : Matrix ZZ  <--- ZZ

The $15$-th toric divisors on a surface lies over normal toric varieties with $8$ irreducible torus-invariant divisors.

i15 : D3 = smallAmpleToricDivisor (2,15);

o15 : ToricDivisor on normalToricVariety ({{1, 0}, {-1, 0}, {1, 2}, {0, 1}, {1, 1}, {0, -1}, {-1, -1}, {-1, -2}}, {{0, 4}, {0, 5}, {1, 3}, {1, 6}, {2, 3}, {2, 4}, {5, 7}, {6, 7}})
i16 : assert isVeryAmple D3
i17 : X3 = variety D3;
i18 : assert (isSmooth X3 and isProjective X3)
i19 : rays X3

o19 = {{1, 0}, {-1, 0}, {1, 2}, {0, 1}, {1, 1}, {0, -1}, {-1, -1}, {-1, -2}}

o19 : List
i20 : D3

o20 = 3*X3  + X3  + X3  + 3*X3  + 2*X3  + 4*X3
          0     1     4       5       6       7

o20 : ToricDivisor on X3
i21 : latticePoints D3

o21 = | 0 1 0 -2 -1 1 0 -3 -2 -1 -3 -2 |
      | 0 0 1 1  1  1 2 2  2  2  3  3  |

               2        12
o21 : Matrix ZZ  <--- ZZ

Last, $25$ toric divisors on a surface lies over Hirzebruch surfaces.

i22 : D4 = smallAmpleToricDivisor (2,30);

o22 : ToricDivisor on normalToricVariety ({{1, 0}, {-1, 0}, {0, 1}, {5, -1}}, {{0, 2}, {0, 3}, {1, 2}, {1, 3}})
i23 : assert isVeryAmple D4
i24 : X4 = variety D4;
i25 : assert (isSmooth X4 and isProjective X4)
i26 : rays X4

o26 = {{1, 0}, {-1, 0}, {0, 1}, {5, -1}}

o26 : List
i27 : D4

o27 = X4  + 2*X4
        1       3

o27 : ToricDivisor on X4
i28 : latticePoints D4

o28 = | 0 1 0 1 0 1 1 1 1 1 1 |
      | 0 0 1 1 2 2 3 4 5 6 7 |

               2        11
o28 : Matrix ZZ  <--- ZZ

The first $99$ toric divisors on a threefold embed a projective bundle into projective space.

i29 : D5 = smallAmpleToricDivisor(3,75);

o29 : ToricDivisor on normalToricVariety ({{1, 0, 0}, {-1, 0, 0}, {0, 1, 0}, {1, 1, 0}, {0, -1, 0}, {-1, -1, 0}, {0, 0, 1}, {0, 0, -1}}, {{0, 3, 6}, {0, 3, 7}, {0, 4, 6}, {0, 4, 7}, {1, 2, 6}, {1, 2, 7}, {1, 5, 6}, {1, 5, 7}, {2, 3, 6}, {2, 3, 7}, {4, 5, 6}, {4, 5, 7}})
i30 : assert isVeryAmple D5
i31 : X5 = variety D5;
i32 : assert (isSmooth X5 and isProjective X5)
i33 : assert (# rays X5 === 8)
i34 : D5

o34 = 2*X5  + X5  + 2*X5  + X5  + X5
          0     3       4     5     7

o34 : ToricDivisor on X5
i35 : latticePoints D5

o35 = | 0 -1 0 -2 -1 -2 -1 0 -1 0 -2 -1 -2 -1 |
      | 0 0  1 1  1  2  2  0 0  1 1  1  2  2  |
      | 0 0  0 0  0  0  0  1 1  1 1  1  1  1  |

               3        14
o35 : Matrix ZZ  <--- ZZ

The last $4$ toric divisors on a threefold embed a blow-up of a projective bundle at few points into projective space.

i36 : D6 = smallAmpleToricDivisor (3,102);

o36 : ToricDivisor on normalToricVariety ({{1, 0, 0}, {0, 1, 0}, {0, -1, 0}, {0, 0, 1}, {1, 1, 1}, {-1, 0, -1}, {-1, -1, -1}}, {{0, 1, 4}, {0, 1, 5}, {0, 2, 3}, {0, 2, 6}, {0, 3, 4}, {0, 5, 6}, {1, 3, 4}, {1, 3, 5}, {2, 3, 6}, {3, 5, 6}})
i37 : assert(isVeryAmple D6)
i38 : X6 = variety D6;
i39 : assert (isSmooth X6 and isProjective X6)
i40 : assert (# rays X6 === 7)
i41 : D6

o41 = X6  + 2*X6  + X6  + 2*X6
        0       2     5       6

o41 : ToricDivisor on X6
i42 : latticePoints D6

o42 = | 0 1 0 -1 1 0 -1 0 -1 0 -1 -1 -1 -1 |
      | 0 0 1 1  1 2 2  0 0  1 1  2  0  1  |
      | 0 0 0 0  0 0 0  1 1  1 1  1  2  2  |

               3        14
o42 : Matrix ZZ  <--- ZZ

Acknowledgements

We thank Milena Hering for her help creating the database.

See also