next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: isNef(ToricDivisor)

isNef(ToricDivisor) -- whether a torus-invariant Weil divisor is nef

Synopsis

Description

A $\QQ$-Cartier divisor is nef (short for numerically effective or numerically eventually free) if the intersection product of the divisor with every complete irreducible curve is nonnegative. The definition depends only on the numerical equivalence class of the divisor. For a torus-invariant $\QQ$-Cartier divisor on a complete normal toric variety, the following are equivalent:

  • the divisor is nef;
  • some positive integer multiply of the divisor is Cartier and basepoint free;
  • the real piecewise linear support function associated to the divisor is convex.

A torus-invariant Cartier divisor is nef if and only if it is basepoint free; in other words, the associated line bundle is generated by its global sections.

On a Hirzebruch surface, three of the four torus-invariant irreducible divisors are nef, and none are ample.

i1 : X1 = hirzebruchSurface 2;
i2 : assert (isNef X1_0 and not isAmple X1_0)
i3 : assert not isNef X1_1
i4 : assert (isNef X1_2 and not isAmple X1_2)
i5 : assert (isNef X1_3 and not isAmple X1_3)

Not every $\QQ$-Cartier nef divisor is basepoint free.

i6 : X2 = weightedProjectiveSpace {2,3,5};
i7 : D = X2_1 - X2_0

o7 = - X2  + X2
         0     1

o7 : ToricDivisor on X2
i8 : assert (isNef D and HH^0(X2, OO D) == 0)
i9 : assert all (dim X2, i -> HH^i(X2, OO D) == 0)
i10 : assert not isCartier D
i11 : assert isCartier (30*D)
i12 : HH^0 (X2, OO (30*D))

        21
o12 = QQ

o12 : QQ-module, free
i13 : assert all (dim X2 -1, i -> HH^(i+1)(X2, OO (30*D)) == 0)

There are smooth complete normal toric varieties with no nontrivial nef divisors.

i14 : X3 = normalToricVariety({{1,0,0},{0,1,0},{0,0,1},{0,-1,2},{0,0,-1},{-1,1,-1},{-1,0,-1},{-1,-1,0}},{{0,1,2},{0,2,3},{0,3,4},{0,4,5},{0,1,5},{1,2,7},{2,3,7},{3,4,7},{4,5,6},{4,6,7},{5,6,7},{1,5,7}});
i15 : assert (isComplete X3 and not isProjective X3)
i16 : assert not any (#rays X3, i -> isNef X3_i)
i17 : assert isNef (0*X3_1)
i18 : assert (nefGenerators X3 == 0)

The most basic vanishing theorem for normal toric varieties states that the higher cohomology of coherent sheaf associated to a nef divisor is zero.

i19 : X4 = kleinschmidt (9,{1,2,3});
i20 : assert (isNef X4_0 and not isAmple X4_0)
i21 : assert all (dim X4 - 1, i -> HH^(i+1)(X4, OO X4_0) == 0)
i22 : D = X4_0 + X4_4

o22 = X4  + X4
        0     4

o22 : ToricDivisor on X4
i23 : assert (isNef D and isAmple D)
i24 : assert all (dim X4 - 1, i -> HH^(i+1)(X4, OO D) == 0)

See also