next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: ctop(CoherentSheaf)

ctop(CoherentSheaf) -- compute the top Chern class of a coherent sheaf

Synopsis

Description

For a coherent sheaf F on a variety X, the top Chern class is chern (dim X, F).

On projective space, the coefficient of the top Chern class of the tangent bundle is the 1 plus dimension of the variety.

i1 : X0 = toricProjectiveSpace 5;
i2 : A0 = intersectionRing X0;
i3 : ctop dual cotangentSheaf X0

       5
o3 = 6t
       5

o3 : A0
i4 : assert all (5, d -> (leadCoefficient ctop dual cotangentSheaf toricProjectiveSpace (d+1)) == d+2)
i5 : assert all (5, d -> (
             F := dual cotangentSheaf toricProjectiveSpace (d+1);
             chern (d+1, F) === ctop F
             )
         )

On a complete smooth normal toric variety, the top Chern class is a sum of the classes corresponding to maximal cones in the underlying fan.

i6 : X1 = smoothFanoToricVariety (4, 50);
i7 : A1 = intersectionRing X1;
i8 : E1 = cotangentSheaf X1

o8 = cokernel {2, 0, 0, 0} | 0      x_0x_4x_7 x_0x_3x_6x_7 0            0            x_0x_3x_5x_7 0         0         0         0         |
              {0, 0, 2, 0} | x_3x_4 0         0            x_0x_2x_3x_7 x_0x_1x_3x_7 0            0         0         0         0         |
              {0, 2, 0, 0} | x_5    0         0            0            0            0            x_0x_2x_7 x_0x_1x_7 0         0         |
              {0, 2, 0, 0} | -x_6   0         0            0            0            0            0         0         x_0x_2x_7 x_0x_1x_7 |
              {0, 0, 0, 2} | 0      x_1       0            0            0            0            x_3x_6    0         x_3x_5    0         |
              {0, 0, 0, 2} | 0      -x_2      0            0            0            0            0         x_3x_6    0         x_3x_5    |
              {0, 0, 0, 2} | 0      0         x_1          x_5          0            0            -x_4      0         0         0         |
              {0, 0, 0, 2} | 0      0         -x_2         0            x_5          0            0         -x_4      0         0         |
              {0, 0, 0, 2} | 0      0         0            -x_6         0            x_1          0         0         -x_4      0         |
              {0, 0, 0, 2} | 0      0         0            0            -x_6         -x_2         0         0         0         -x_4      |

                                           1                      1                      2                      6
o8 : coherent sheaf on X1, quotient of OO    (-2, 0, 0, 0) ++ OO    (0, 0, -2, 0) ++ OO    (0, -2, 0, 0) ++ OO    (0, 0, 0, -2)
                                         X1                     X1                     X1                     X1
i9 : f1 = ctop E1

     16 4
o9 = --t
      3 7

o9 : A1
i10 : assert (f1 === sum(max X1, s -> product(s, i -> -A1_i)))
i11 : assert (f1 === chern (dim X1, E1))

See also