next | previous | forward | backward | up | top | index | toc | Macaulay2 website
ModuleDeformations :: deformMCMModule(Module,RingMap)

deformMCMModule(Module,RingMap) -- deformation in the relative case

Synopsis

Description

This interface to deformMCMModule constructs a versal deformation of M0 in the general case. That is, there is given a map of varieties $\phi:Y \rightarrow{} \Sigma$ and a module M0 defined over the fibre over 0 of $\phi$. A versal deformation of M0 is then constructed in the deformation theory so defined. Thus its inputs consist of M0 and a ring homomorphism $\phi^*$ representing the map $\phi:Y \rightarrow{} \Sigma$. The procedure requires that M0 be an MCM module over the ring \mathcal{O}_Y/\phi^*(m_\Sigma), where m_\Sigma is the ideal generated by the variables of \mathcal{O}_\Sigma. Otherwise an error will result.

If M0 is free, then deformMCMModule returns (S,M), where S is the source of phi and M is a free module over the ambient ring of Y, generated in the same degrees as M0.

i1 : OSigma = QQ[x, Degrees=>{2}];
i2 : OY = QQ[y,z,x, Degrees=>{2,3,2}]/(z^2-(y-x)*y^2);
i3 : phi = map(OY,OSigma, {x})

o3 = map (OY, OSigma, {x})

o3 : RingMap OY <--- OSigma
i4 : use OSigma

o4 = OSigma

o4 : PolynomialRing
i5 : OX = trim (OY/phi(ideal x))

o5 = OX

o5 : QuotientRing
i6 : (OS,M) = deformMCMModule(module ideal (y,z),phi)

o6 = (OS, cokernel {2} | z+xi_1  y2-yx-yxi_2+xxi_2+xi_2^2 |)
                   {3} | -y-xi_2 -z+xi_1                  |

o6 : Sequence
i7 : prune OS

      QQ[x, xi ..xi ]
              1    2
o7 = -----------------
       2       2     3
     xi  + x*xi  + xi
       1       2     2

o7 : QuotientRing
The above example deforms the maximal ideal of the A2 singularity onto the Whitney umbrella $Y$ (whose ring is OY above, of which the former is a hyperplane section given by the fibre over 0 of the map $Y \rightarrow{} \Sigma$ defined by $\phi$ above. The resulting base space S (whose ring OS is part of the output of deformMCMModule) is the Hilbert scheme of one point on the Whitney umbrella, which is isomorphic to $Y$. The substitution y => -xi_2, z => xi_1 shows this isomorphism.

The resulting module $M$, when restricted to the fibre product of $Y$ and $S$ over $\Sigma$, is isomorphic to the ideal defining the diagonal embedding of $Y$.