next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Macaulay2Doc > basic commutative algebra > M2SingularBook > Singular Book 1.8.6

Singular Book 1.8.6 -- Zariski closure of the image

We compute an implicit equation for the surface defined parametrically by the map $f : A^2 \rightarrow{} A^3, (u,v) \mapsto{} (uv,uv^2,u^2)$.
i1 : A = QQ[u,v,x,y,z];
i2 : I = ideal "x-uv,y-uv2,z-u2"

                            2         2
o2 = ideal (- u*v + x, - u*v  + y, - u  + z)

o2 : Ideal of A
i3 : eliminate(I,{u,v})

            4    2
o3 = ideal(x  - y z)

o3 : Ideal of A
This ideal defines the closure of the map $f$, the Whitney umbrella.

Alternatively, we could take the coimage of the ring homomorphism g corresponding to f.

i4 : g = map(QQ[u,v],QQ[x,y,z],{x => u*v, y => u*v^2, z => u^2})

                                       2   2
o4 = map (QQ[u..v], QQ[x..z], {u*v, u*v , u })

o4 : RingMap QQ[u..v] <--- QQ[x..z]
i5 : coimage g

     QQ[x..z]
o5 = --------
      4    2
     x  - y z

o5 : QuotientRing