next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Macaulay2Doc :: Ideal ^ Array

Ideal ^ Array -- bracket power of an ideal

Synopsis

Description

The bracket power of an ideal is defined to be the ideal generated by the image of the generators under the ring homomorphism given by sending a variable to the corresponding power. The array may either be a singleton, as follows:
i1 : R = QQ[a..d];
i2 : I = ideal(a^2*b, a*b^2,c^3,d^5);

o2 : Ideal of R
i3 : I^[3]

             6 3   3 6   9   15
o3 = ideal (a b , a b , c , d  )

o3 : Ideal of R
One may also give an array that is the same length as the number of variables in the ring, as follows:
i4 : I^[2,3,4,5]

             4 2   2 4   6   10
o4 = ideal (a b , a b , c , d  )

o4 : Ideal of R
If your ring is a tower, then the bracket power will raise the outermost variables to powers.
i5 : S = QQ[x,y];
i6 : T = S[z,w];
i7 : I = ideal gens T;

o7 : Ideal of T
i8 : I^[3]

             3   3
o8 = ideal (z , w )

o8 : Ideal of T
i9 : I^[2,3]

             2   2
o9 = ideal (z , w )

o9 : Ideal of T
No check is made to determine whether the function given by exponentiating the generators is a ring homomorphism. Of course, this only is an issue when taking bracket powers of ideals in a quotient ring. One important case where the bracket power is useful is when studying Frobenius powers of ideals, which corresponds to the image of the ideal under the Frobenius automorphism.
i10 : R = ZZ/5[a..d];
i11 : I = minors(2,matrix {{a,b,c},{b,c,d}});

o11 : Ideal of R
i12 : S = R/I;
i13 : J = ideal vars S

o13 = ideal (a, b, c, d)

o13 : Ideal of S
i14 : J^[5]

              5   3          3   5
o14 = ideal (a , a c*d, a*b*d , d )

o14 : Ideal of S

See also