next | previous | forward | backward | up | top | index | toc | Macaulay2 website
EliminationMatrices :: eliminationMatrix

eliminationMatrix -- returns a matrix that represents the image of the map

Synopsis

Description

If the strategy 's' is 'Sylvester':

Refer to sylvesterMatrix

If the strategy 's' is 'Macaulay':

Let $f_1,..,f_n$ be a polynomials two groups of variables $X_1,...,X_n$ and $a_1,...,a_s$ and such that $f_1,...,f_n$ are homogeneous polynomials with respect to the variables $X_1,...,X_n$. This function returns a matrix which is generically (in terms of the parameters $a_1,...,a_s$) surjective such that the gcd of its maximal minors is the Macaulay resultant of $f_1,...,f_n$.

i1 : R=QQ[a_0..a_8,x,y,z]

o1 = R

o1 : PolynomialRing
i2 : f1 = a_0*x+a_1*y+a_2*z

o2 = a x + a y + a z
      0     1     2

o2 : R
i3 : f2 = a_3*x+a_4*y+a_5*z

o3 = a x + a y + a z
      3     4     5

o3 : R
i4 : f3 = a_6*x+a_7*y+a_8*z

o4 = a x + a y + a z
      6     7     8

o4 : R
i5 : M = matrix{{f1,f2,f3}}

o5 = | a_0x+a_1y+a_2z a_3x+a_4y+a_5z a_6x+a_7y+a_8z |

             1       3
o5 : Matrix R  <--- R
i6 : l = {x,y,z}

o6 = {x, y, z}

o6 : List
i7 : MR = eliminationMatrix (l,M, Strategy => Macaulay)

o7 = {1} | a_0 a_3 a_6 |
     {1} | a_1 a_4 a_7 |
     {1} | a_2 a_5 a_8 |

             3       3
o7 : Matrix R  <--- R

If the strategy 's' is 'determinantal':

Compute the determinantal resultant of an (n,m)-matrix (n<m) of homogeneous polynomials over the projective space of dimension (m-r)(n-r), i.e. a condition on the parameters of these polynomials to have rank(M)<r+1.

i8 : R=QQ[a_0..a_5,b_0..b_5,x,y]

o8 = R

o8 : PolynomialRing
i9 : M:=matrix{{a_0*x+a_1*y,a_2*x+a_3*y,a_4*x+a_5*y},{b_0*x+b_1*y,b_2*x+b_3*y,b_4*x+b_5*y}}

o9 = | a_0x+a_1y a_2x+a_3y a_4x+a_5y |
     | b_0x+b_1y b_2x+b_3y b_4x+b_5y |

             2       3
o9 : Matrix R  <--- R
i10 : eliminationMatrix(1,{x,y},M, Strategy => determinantal)

o10 = {2} | -a_2b_0+a_0b_2               -a_4b_0+a_0b_4              
      {2} | -a_3b_0-a_2b_1+a_1b_2+a_0b_3 -a_5b_0-a_4b_1+a_1b_4+a_0b_5
      {2} | -a_3b_1+a_1b_3               -a_5b_1+a_1b_5              
      -----------------------------------------------------------------------
      -a_4b_2+a_2b_4               |
      -a_5b_2-a_4b_3+a_3b_4+a_2b_5 |
      -a_5b_3+a_3b_5               |

              3       3
o10 : Matrix R  <--- R

If the strategy 's' is 'CM2Residual':

Suppose given a homogeneous ideal locally complete intersection Cohen-Macaulay of codimension 2,$J=(g_1,..,g_n)$, such that $I=(f1,..,fm)$ is included in J and (I:J) is a residual intersection. Let H be the matrix that I=J.H. Let R be the matrix of the first syzygies of J. This function computes an elimination matrix corresponding to the residual resultant over V(I) over V(J).

i11 : R = QQ[X,Y,Z,x,y,z]

o11 = R

o11 : PolynomialRing
i12 : F = matrix{{x*y^2,y^3,x*z^2,y^3+z^3}}

o12 = | xy2 y3 xz2 y3+z3 |

              1       4
o12 : Matrix R  <--- R
i13 : G = matrix{{y^2,z^2}}

o13 = | y2 z2 |

              1       2
o13 : Matrix R  <--- R
i14 : M = matrix{{1,0,0},{0,1,0},{0,0,1},{-X,-Y,-Z}}

o14 = | 1  0  0  |
      | 0  1  0  |
      | 0  0  1  |
      | -X -Y -Z |

              4       3
o14 : Matrix R  <--- R
i15 : H = (F//G)*M

o15 = {2} | -Xy+x -Yy+y -Zy   |
      {2} | -Xz   -Yz   -Zz+x |

              2       3
o15 : Matrix R  <--- R
i16 : l = {x,y,z}

o16 = {x, y, z}

o16 : List
i17 : L=eliminationMatrix (l,G,H, Strategy => CM2Residual)

o17 = {3} | 0  0   0  0  0  0  1  0  0  0    0    0    |
      {3} | 0  0   0  0  0  0  -X 1  0  -Y+1 0    0    |
      {3} | 0  0   -Y 0  0  0  -Z 0  1  0    0    0    |
      {3} | -1 0   0  0  0  0  0  -X 0  0    -Y+1 0    |
      {3} | 0  0   X  -Y 0  0  0  -Z -X -Z   0    -Y+1 |
      {3} | 0  0   0  0  -Y -1 0  0  -Z 0    0    0    |
      {3} | X  Y-1 0  0  0  Z  0  0  0  0    0    0    |
      {3} | 0  0   0  X  0  0  0  0  0  0    -Z   0    |
      {3} | 0  0   0  0  X  0  0  0  0  0    0    -Z   |
      {3} | X  Y   0  0  0  Z  0  0  0  0    0    0    |

              10       12
o17 : Matrix R   <--- R
i18 : maxCol L

o18 = {{3} | 0  0   0  0  0  0  1  0  0  0    |, {0, 1, 2, 3, 4, 5, 6, 7, 8,
       {3} | 0  0   0  0  0  0  -X 1  0  -Y+1 |
       {3} | 0  0   -Y 0  0  0  -Z 0  1  0    |
       {3} | -1 0   0  0  0  0  0  -X 0  0    |
       {3} | 0  0   X  -Y 0  0  0  -Z -X -Z   |
       {3} | 0  0   0  0  -Y -1 0  0  -Z 0    |
       {3} | X  Y-1 0  0  0  Z  0  0  0  0    |
       {3} | 0  0   0  X  0  0  0  0  0  0    |
       {3} | 0  0   0  0  X  0  0  0  0  0    |
       {3} | X  Y   0  0  0  Z  0  0  0  0    |
      -----------------------------------------------------------------------
      9}}

o18 : List

If the strategy 's' is 'ciResidual':

This function basically computes the matrix of the first application in the resolution of (I:J) given in the article of Bruns, Kustin and Miller: 'The resolution of the generic residual intersection of a complete intersection', Journal of Algebra 128.

The first argument is a list of homogeneous polynomials $J=(g_1,..,g_m)$ forming a complete intersection with respect to the variables 'varList'. Given a system of homogeneous $I=(f_1,..,f_n)$ such that I is included in J and (I:J) is a residual intersection, one wants to to compute a sort of resultant of (I:J). The second argument is the matrix M such that I=J.M. The output is a generically (with respect to the other variables than 'varList') surjective matrix such that the determinant of a maximal minor is a multiple of the resultant of I on the closure of the complementary of V(J) in V(I). Such a minor can be obtain with maxMinor.

i19 : R=QQ[a_0,a_1,a_2,a_3,a_4,b_0,b_1,b_2,b_3,b_4,c_0,c_1,c_2,c_3,c_4,x,y,z]

o19 = R

o19 : PolynomialRing
i20 : G=matrix{{z,x^2+y^2}}

o20 = | z x2+y2 |

              1       2
o20 : Matrix R  <--- R
i21 : H=matrix{{a_0*z+a_1*x+a_2*y,b_0*z+b_1*x+b_2*y,c_0*z+c_1*x+c_2*y},{a_3,b_3,c_3}}

o21 = | a_1x+a_2y+a_0z b_1x+b_2y+b_0z c_1x+c_2y+c_0z |
      | a_3            b_3            c_3            |

              2       3
o21 : Matrix R  <--- R
i22 : L=eliminationMatrix ({x,y,z},G,H, Strategy => ciResidual)

o22 = {2} | a_3 b_3 c_3 -a_3b_1+a_1b_3 0              0             
      {2} | 0   0   0   -a_3b_2+a_2b_3 -a_3b_1+a_1b_3 0             
      {2} | a_1 b_1 c_1 -a_3b_0+a_0b_3 0              -a_3b_1+a_1b_3
      {2} | a_3 b_3 c_3 0              -a_3b_2+a_2b_3 0             
      {2} | a_2 b_2 c_2 0              -a_3b_0+a_0b_3 -a_3b_2+a_2b_3
      {2} | a_0 b_0 c_0 0              0              -a_3b_0+a_0b_3
      -----------------------------------------------------------------------
      -a_3c_1+a_1c_3 0              0              -b_3c_1+b_1c_3
      -a_3c_2+a_2c_3 -a_3c_1+a_1c_3 0              -b_3c_2+b_2c_3
      -a_3c_0+a_0c_3 0              -a_3c_1+a_1c_3 -b_3c_0+b_0c_3
      0              -a_3c_2+a_2c_3 0              0             
      0              -a_3c_0+a_0c_3 -a_3c_2+a_2c_3 0             
      0              0              -a_3c_0+a_0c_3 0             
      -----------------------------------------------------------------------
      0              0              |
      -b_3c_1+b_1c_3 0              |
      0              -b_3c_1+b_1c_3 |
      -b_3c_2+b_2c_3 0              |
      -b_3c_0+b_0c_3 -b_3c_2+b_2c_3 |
      0              -b_3c_0+b_0c_3 |

              6       12
o22 : Matrix R  <--- R

If the strategy is 'byResolution':

This function computes the matrix of the first application in the resolution of (I:J) given by resolutionin degree regularity

i23 : R=QQ[a_0,a_1,a_2,a_3,a_4,b_0,b_1,b_2,b_3,b_4,c_0,c_1,c_2,c_3,c_4,x,y,z]

o23 = R

o23 : PolynomialRing
i24 : G=matrix{{z,x^2+y^2}}

o24 = | z x2+y2 |

              1       2
o24 : Matrix R  <--- R
i25 : H=matrix{{a_0*z+a_1*x+a_2*y,b_0*z+b_1*x+b_2*y,c_0*z+c_1*x+c_2*y},{a_3,b_3,c_3}}

o25 = | a_1x+a_2y+a_0z b_1x+b_2y+b_0z c_1x+c_2y+c_0z |
      | a_3            b_3            c_3            |

              2       3
o25 : Matrix R  <--- R
i26 : L=eliminationMatrix ({x,y,z},G,H, Strategy => byResolution)

o26 = {2} | a_3b_1-a_1b_3 0             0             a_3c_1-a_1c_3
      {2} | a_3b_2-a_2b_3 a_3b_1-a_1b_3 0             a_3c_2-a_2c_3
      {2} | a_3b_0-a_0b_3 0             a_3b_1-a_1b_3 a_3c_0-a_0c_3
      {2} | 0             a_3b_2-a_2b_3 0             0            
      {2} | 0             a_3b_0-a_0b_3 a_3b_2-a_2b_3 0            
      {2} | 0             0             a_3b_0-a_0b_3 0            
      -----------------------------------------------------------------------
      0             0             b_3c_1-b_1c_3 0             0            
      a_3c_1-a_1c_3 0             b_3c_2-b_2c_3 b_3c_1-b_1c_3 0            
      0             a_3c_1-a_1c_3 b_3c_0-b_0c_3 0             b_3c_1-b_1c_3
      a_3c_2-a_2c_3 0             0             b_3c_2-b_2c_3 0            
      a_3c_0-a_0c_3 a_3c_2-a_2c_3 0             b_3c_0-b_0c_3 b_3c_2-b_2c_3
      0             a_3c_0-a_0c_3 0             0             b_3c_0-b_0c_3
      -----------------------------------------------------------------------
      a_3 b_3 c_3 |
      0   0   0   |
      a_1 b_1 c_1 |
      a_3 b_3 c_3 |
      a_2 b_2 c_2 |
      a_0 b_0 c_0 |

              6       12
o26 : Matrix R  <--- R

See also

Ways to use eliminationMatrix :

For the programmer

The object eliminationMatrix is a method function with options.