next | previous | forward | backward | up | top | index | toc | Macaulay2 website
NormalToricVarieties :: isAmple(ToricDivisor)

isAmple(ToricDivisor) -- whether a torus-invariant Weil divisor is ample

Synopsis

Description

A Cartier divisor is very ample when it is basepoint free and the map arising from its complete linear series is a closed embedding. A Cartier divisor is ample when some positive integer multiple is very ample. For a torus-invariant Cartier divisor on a complete normal toric variety, the following conditions are equivalent:

  • the divisor is ample;
  • the real piecewise linear support function associated to the divisor is strictly convex;
  • the lattice polytope corresponding to the divisor is full-dimensional and its normal fan equals the fan associated to the underlying toric variety;
  • the intersection product of the divisor with every torus-invariant irreducible curve is positive.

On projective space, every torus-invariant irreducible divisor is ample.

i1 : PP3 = toricProjectiveSpace 3;
 
i2 : assert all (# rays PP3, i -> isAmple PP3_i)

On a Hirzebruch surface, none of the torus-invariant irreducible divisors are ample.

i3 : X1 = hirzebruchSurface 2;
 
i4 : assert not any (# rays X1, i -> isAmple X1_i)
 
i5 : D = X1_2 + X1_3

o5 = X1  + X1
       2     3

o5 : ToricDivisor on X1
 
i6 : assert isAmple D
 
i7 : assert isProjective X1

A normal toric variety is Fano if and only if its anticanonical divisors, namely minus the sum of its torus-invariant irreducible divisors, is ample.

i8 : X2 = smoothFanoToricVariety (3,5);
 
i9 : K = toricDivisor X2

o9 = - X2  - X2  - X2  - X2  - X2  - X2
         0     1     2     3     4     5

o9 : ToricDivisor on X2
 
i10 : assert isAmple (- K)
 
i11 : X3 = kleinschmidt (9,{1,2,3});
 
i12 : K = toricDivisor X3

o12 = - X3  - X3  - X3  - X3  - X3  - X3  - X3  - X3  - X3  - X3  - X3
          0     1     2     3     4     5     6     7     8     9     10

o12 : ToricDivisor on X3
 
i13 : assert isAmple (-K)

See also