next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Macaulay2Doc :: eulers(CoherentSheaf)

eulers(CoherentSheaf) -- list the sectional Euler characteristics

Synopsis

Description

Computes a list of the successive sectional Euler characteristics of a coherent sheaf, the i-th entry on the list being the Euler characteristic of the i-th generic hyperplane restriction of E

The Horrocks-Mumford bundle on the projective fourspace:

i1 : R = QQ[x_0..x_4];
i2 : a = {1,0,0,0,0}

o2 = {1, 0, 0, 0, 0}

o2 : List
i3 : b = {0,1,0,0,1}

o3 = {0, 1, 0, 0, 1}

o3 : List
i4 : c = {0,0,1,1,0}

o4 = {0, 0, 1, 1, 0}

o4 : List
i5 : M1 = matrix table(5,5, (i,j)-> x_((i+j)%5)*a_((i-j)%5))

o5 = | x_0 0   0   0   0   |
     | 0   x_2 0   0   0   |
     | 0   0   x_4 0   0   |
     | 0   0   0   x_1 0   |
     | 0   0   0   0   x_3 |

             5       5
o5 : Matrix R  <--- R
i6 : M2 = matrix table(5,5, (i,j)-> x_((i+j)%5)*b_((i-j)%5))

o6 = | 0   x_1 0   0   x_4 |
     | x_1 0   x_3 0   0   |
     | 0   x_3 0   x_0 0   |
     | 0   0   x_0 0   x_2 |
     | x_4 0   0   x_2 0   |

             5       5
o6 : Matrix R  <--- R
i7 : M3 = matrix table(5,5, (i,j)-> x_((i+j)%5)*c_((i-j)%5))

o7 = | 0   0   x_2 x_3 0   |
     | 0   0   0   x_4 x_0 |
     | x_2 0   0   0   x_1 |
     | x_3 x_4 0   0   0   |
     | 0   x_0 x_1 0   0   |

             5       5
o7 : Matrix R  <--- R
i8 : M = M1 | M2 | M3;

             5       15
o8 : Matrix R  <--- R
i9 : betti (C=res coker M)

            0  1  2  3  4 5
o9 = total: 5 15 29 37 20 2
         0: 5 15 10  2  . .
         1: .  .  4  .  . .
         2: .  . 15 35 20 .
         3: .  .  .  .  . 2

o9 : BettiTally
i10 : N = transpose submatrix(C.dd_3,{10..28},{2..36});

              35       19
o10 : Matrix R   <--- R
i11 : betti (D=res coker N)

              0  1  2  3  4 5
o11 = total: 35 19 19 35 20 2
         -5: 35 15  .  .  . .
         -4:  .  4  .  .  . .
         -3:  .  .  .  .  . .
         -2:  .  .  .  .  . .
         -1:  .  .  .  .  . .
          0:  .  .  4  .  . .
          1:  .  . 15 35 20 .
          2:  .  .  .  .  . 2

o11 : BettiTally
i12 : Pfour = Proj(R)

o12 = Pfour

o12 : ProjectiveVariety
i13 : HorrocksMumford = sheaf(coker D.dd_3);
i14 : HH^0(HorrocksMumford(1))

o14 = 0

o14 : QQ-module
i15 : HH^0(HorrocksMumford(2))

        4
o15 = QQ

o15 : QQ-module, free
i16 : eulers(HorrocksMumford(2))

o16 = {2, 12, 12, 7, 2}

o16 : List

See also