next | previous | forward | backward | up | top | index | toc | Macaulay2 website
HighestWeights :: highestWeightsDecomposition(Module,List,List)

highestWeightsDecomposition(Module,List,List) -- decompose a module with a semisimple Lie group action

Synopsis

Description

Let $G$ be a semisimple algebraic group which acts on a polynomial ring $R$ compatibly with the grading. Let $T\subseteq G$ be a maximal torus and assume the variables in $R$ are weight vectors for the action of $T$.

Suppose M is a finitely generated module over $R$ which is stable under the action of $G$. We assume that M was input in Macaulay2 using a specific presentation $\phi : E\rightarrow F$, where $E$ and $F$ are graded free $R$-modules of finite rank. Moreover assume the coordinate basis of $F$ is a homogeneous basis of weight vectors for the action of $T$ and the weight of the $j$-th basis vector is $w_j$.

Use this function to obtain the decomposition of a graded component of M. The input consists of three parameter: the module M, the (multi)degree of the graded component, and the list of weights $\{w_j\}$.

The output is a tally whose keys are the highest weights of certain irreducible representations and whose values are the multiplicities of those representations.

In the following example, the polynomial ring R is the symmetric algebra over $\mathbb{C}^2 \otimes \mathbb{C}^4$, with the natural action of $G=SL_2 (\mathbb{C}) \times SL_4 (\mathbb{C})$. The map $\phi$ is the unique (up to scalars) equivariant map $\mathbb{C}^4 \otimes R(-1) \rightarrow (\mathbb{C}^2)^* \otimes R$. If $\{f_1,f_2\}$ and $\{e_1,e_2,e_3,e_4\}$ are the coordinate bases of $\mathbb{C}^2$ and $\mathbb{C}^4$ respectively, then the matrix of $\phi$ with respect to the bases $\{f_1^*,f_2^*\}$ and $\{e_1,e_2,e_3,e_4\}$ is a generic matrix of indeterminates.

i1 : R=QQ[x_(1,1)..x_(4,2)];
i2 : D=dynkinType{{"A",1},{"A",3}};
i3 : U={{1,1,0,0},{-1,1,0,0},{1,-1,1,0},{-1,-1,1,0},{1,0,-1,1},{-1,0,-1,1},{1,0,0,-1},{-1,0,0,-1}};
i4 : setWeights(R,D,U);
i5 : G=genericMatrix(R,2,4);

             2       4
o5 : Matrix R  <--- R
i6 : M=coker G

o6 = cokernel | x_(1,1) x_(2,1) x_(3,1) x_(4,1) |
              | x_(1,2) x_(2,2) x_(3,2) x_(4,2) |

                            2
o6 : R-module, quotient of R
i7 : highestWeightsDecomposition(M,{2},{{-1,0,0,0},{1,0,0,0}})

o7 = Tally{{3, 2, 0, 0} => 1}

o7 : Tally

This shows that the component of M of degree 2 is the representation $S_3 \mathbb{C}^3 \otimes S_2 \mathbb{C}^4$. Here $S_\lambda$ denotes the Schur functor corresponding to the partition $\lambda$.

When the polynomial ring is $\mathbb{Z}$-graded the degree can be given as an integer instead of a list. Moreover, in the $\mathbb{Z}$-graded case, one can decompose a range of degrees all at once as illustrated below.

i8 : highestWeightsDecomposition(M,2,{{-1,0,0,0},{1,0,0,0}})

o8 = Tally{{3, 2, 0, 0} => 1}

o8 : Tally
i9 : highestWeightsDecomposition(M,0,4,{{-1,0,0,0},{1,0,0,0}})

o9 = HashTable{0 => Tally{{1, 0, 0, 0} => 1}}
               1 => Tally{{2, 1, 0, 0} => 1}
               2 => Tally{{3, 2, 0, 0} => 1}
               3 => Tally{{4, 3, 0, 0} => 1}
               4 => Tally{{5, 4, 0, 0} => 1}

o9 : HashTable