next | previous | forward | backward | up | top | index | toc | Macaulay2 website
HighestWeights :: Example 4

Example 4 -- The Eisenbud-Fløystad-Weyman complex

We construct and decompose the Eisenbud-Fløystad-Weyman complex of type (0,2,3,6) over a polynomial ring in 3 variables. The ring can be identified with $Sym(E)$, where $E$ is a complex vector space of dimension 3. The ring and the complex carry an action of $SL(E)$.

The complex is constructed using the package PieriMaps. For more information on these complexes, we invite the reader to consult the documentation of that package and the accompanying article.

i1 : R=QQ[x,y,z];
i2 : L={{1,0},{-1,1},{0,-1}};
i3 : D=dynkinType{{"A",2}};
i4 : setWeights(R,D,L)

o4 = Tally{{1, 0} => 1}

o4 : Tally
i5 : loadPackage "PieriMaps";
i6 : f=pureFree({0,2,3,6},R)

o6 = | 12x2 0    0    6xy 0   0   6xz   0    0   2y2 0   0   2yz  0    0  
     | 0    12x2 0    0   6xy 0   0     6xz  0   0   2y2 0   0    2yz  0  
     | 0    0    12x2 0   0   6xy 0     0    6xz 0   0   2y2 0    0    2yz
     | 0    0    0    0   6x2 0   -12x2 0    0   0   8xy 0   -8xy 4xz  0  
     | 0    0    0    0   0   6x2 0     -3x2 0   0   0   8xy 0    -2xy 4xz
     | 0    0    0    0   0   0   0     0    0   0   0   2x2 0    -x2  0  
     ------------------------------------------------------------------------
     2z2   0    0   0   0   0    0   0    0   0    0   0   |
     0     2z2  0   0   0   0    0   0    0   0    0   0   |
     0     0    2z2 0   0   0    0   0    0   0    0   0   |
     -16xz 0    0   6y2 0   4yz  0   2z2  0   0    0   0   |
     0     -4xz 0   0   6y2 -y2  4yz -2yz 2z2 0    0   0   |
     2x2   0    0   0   6xy -2xy 2xz -2xz 0   12y2 6yz 2z2 |

             6       27
o6 : Matrix R  <--- R

The matrix above is a presentation of the module whose resolution is the complex in the title. The rows of the matrix are indexed by standard tableaux of shape $(2,2)$ and entries from $\{0,1,2\}$. The weight of one such tableau is $m_0*L_0+m_1*L_1+m_2*L_2$, where $m_i$ is the multiplicity of $i$ in the tableau. The command below generates all the weights.

i7 : W=apply(apply(standardTableaux(3, {2,2}), flatten), i->sum(apply(i,j->L_j)))

o7 = {{0, 2}, {1, 0}, {2, -2}, {-1, 1}, {0, -1}, {-2, 0}}

o7 : List

Next we generate the resolution and obtain its decomposition.

i8 : EFW=res coker f; betti EFW

            0  1  2 3
o9 = total: 6 27 24 3
         0: 6  .  . .
         1: . 27 24 .
         2: .  .  . .
         3: .  .  . 3

o9 : BettiTally
i10 : highestWeightsDecomposition(EFW,0,W)

o10 = HashTable{0 => HashTable{{0} => Tally{{0, 2} => 1}}}
                1 => HashTable{{2} => Tally{{2, 2} => 1}}
                2 => HashTable{{3} => Tally{{1, 3} => 1}}
                3 => HashTable{{6} => Tally{{1, 0} => 1}}

o10 : HashTable

We conclude that with the action of $SL(E)$ the complex has the following structure: $$S_{2,2} E \otimes R \leftarrow S_{4,2} E \otimes R(-2) \leftarrow S_{4,3} E \otimes R(-3) \leftarrow E \otimes R(-6) \leftarrow 0$$ where $S_\lambda$ denotes the Schur functor associated with the partition $\lambda$.