next | previous | forward | backward | up | top | index | toc | Macaulay2 website
HighestWeights :: Example 3

Example 3 -- A multigraded Eagon-Northcott complex

Let $E={\mathbb C}^3$ with coordinate basis $\{e_1,e_2,e_3\}$, $F={\mathbb C}^4$ with coordinate basis $\{f_1,\ldots,f_4\}$ and $H={\mathbb C}^2$ with coordinate basis $\{h_1,h_2\}$. Denote $R$ the symmetric algebra $Sym((E\oplus F)\otimes H)$; $R$ is a polynomial ring with variables $x_{i,j} = e_i\otimes h_j$ and $y_{i,j} = f_i\otimes h_j$. We take the variables $x_{i,j}$ to have degree $(1,0)$ and the variables $y_{i,j}$ to have degree $(0,1)$. Let $G$ be a $2\times 7$ generic matrix of variables in $R$ and $I$ the ideal generated by the $2\times 2$ minors of $G$. The minimal free resoluiton of $I$ is an example of an Eagon-Northcott complex (see Eisenbud - Commutative Algebra, Appendix A2.6).

i1 : R=QQ[x_(1,1)..x_(3,2),y_(1,1)..y_(4,2),Degrees=>{6:{1,0},8:{0,1}}]

o1 = R

o1 : PolynomialRing
i2 : G=genericMatrix(R,2,3)|genericMatrix(R,y_(1,1),2,4)

o2 = | x_(1,1) x_(2,1) x_(3,1) y_(1,1) y_(2,1) y_(3,1) y_(4,1) |
     | x_(1,2) x_(2,2) x_(3,2) y_(1,2) y_(2,2) y_(3,2) y_(4,2) |

             2       7
o2 : Matrix R  <--- R
i3 : I=minors(2,G);

o3 : Ideal of R
i4 : EN=res I; betti EN

            0  1  2   3  4  5 6
o5 = total: 1 21 70 105 84 35 6
         0: 1  .  .   .  .  . .
         1: . 21 70 105 84 35 6

o5 : BettiTally

Notice how the first three columns of $G$ involve only the $x_{i,j}$ variables while the other columns involve only the $y_{i,j}$ variables. In fact, $G$ is the matrix of the map $$\phi : E\otimes R(-1,0) \oplus F\otimes R(0,-1) \rightarrow H^* \otimes R, e_i \otimes 1 \mapsto \sum_{k=1}^2 h_k^* \otimes x_{i,k}, f_j \otimes 1 \mapsto \sum_{k=1}^2 h_k^* \otimes y_{j,k}$$ with respect to the bases $\{e_1\otimes 1,\ldots,e_3\otimes 1,f_1\otimes 1,\ldots,f_4\otimes 1\}$ of the domain and $\{h_1^*\otimes 1,h_2^*\otimes 1\}$ of the codomain.

The ring $R$ carries a degree compatible action of $SL_3 ({\mathbb C}) \times SL_4 ({\mathbb C}) \times SL_2 ({\mathbb C})$. Notice how the $SL_3 ({\mathbb C})$ factor acts non trivially on $E$, i.e., on the variables $x_{i,j}$, and trivially on $F$, i.e., on the variables $y_{i,j}$. The opposite holds for the $SL_4 ({\mathbb C})$ factor. The map $\phi$ is $G$-equivariant and so the ideal generated by the $2\times 2$ of $\phi$ inherits the $G$-action on $R$.

The weight of $x_{i,j} = e_i\otimes h_j$ is obtained by concatenating the weight of $e_i$ with the trivial weight {0,0,0} for the action of $SL_4 ({\mathbb C})$ and then with the weight of $h_j$. Similarly the weight of $y_{i,j} = f_i\otimes h_j$ is obtained by concatenating the trivial weight {0,0} for the action of $SL_3 ({\mathbb C})$ with the weight of $f_i$ and then with the weight of $h_j$. As in Example 2, we automatize the process as illustrated below and then we attach the list of weights to the ring $R$.

i6 : e={{1,0},{-1,1},{0,-1}}

o6 = {{1, 0}, {-1, 1}, {0, -1}}

o6 : List
i7 : f={{1,0,0},{-1,1,0},{0,-1,1},{0,0,-1}}

o7 = {{1, 0, 0}, {-1, 1, 0}, {0, -1, 1}, {0, 0, -1}}

o7 : List
i8 : h={{1},{-1}}

o8 = {{1}, {-1}}

o8 : List
i9 : W=(flatten table(e,h,(u,v)->u|{0,0,0}|v))|(flatten table(f,h,(u,v)->{0,0}|u|v))

o9 = {{1, 0, 0, 0, 0, 1}, {1, 0, 0, 0, 0, -1}, {-1, 1, 0, 0, 0, 1}, {-1, 1,
     ------------------------------------------------------------------------
     0, 0, 0, -1}, {0, -1, 0, 0, 0, 1}, {0, -1, 0, 0, 0, -1}, {0, 0, 1, 0, 0,
     ------------------------------------------------------------------------
     1}, {0, 0, 1, 0, 0, -1}, {0, 0, -1, 1, 0, 1}, {0, 0, -1, 1, 0, -1}, {0,
     ------------------------------------------------------------------------
     0, 0, -1, 1, 1}, {0, 0, 0, -1, 1, -1}, {0, 0, 0, 0, -1, 1}, {0, 0, 0, 0,
     ------------------------------------------------------------------------
     -1, -1}}

o9 : List
i10 : D=dynkinType{{"A",2},{"A",3},{"A",1}}; setWeights(R,D,W)

o11 = Tally{{0, 0, 1, 0, 0, 1} => 1}
            {1, 0, 0, 0, 0, 1} => 1

o11 : Tally

Now we decompose the resolution of $I$.

i12 : highestWeightsDecomposition(EN)

o12 = HashTable{0 => HashTable{{0, 0} => Tally{{0, 0, 0, 0, 0, 0} => 1}}}
                1 => HashTable{{0, 2} => Tally{{0, 0, 0, 1, 0, 0} => 1}}
                               {1, 1} => Tally{{1, 0, 1, 0, 0, 0} => 1}
                               {2, 0} => Tally{{0, 1, 0, 0, 0, 0} => 1}
                2 => HashTable{{0, 3} => Tally{{0, 0, 0, 0, 1, 1} => 1}}
                               {1, 2} => Tally{{1, 0, 0, 1, 0, 1} => 1}
                               {2, 1} => Tally{{0, 1, 1, 0, 0, 1} => 1}
                               {3, 0} => Tally{{0, 0, 0, 0, 0, 1} => 1}
                3 => HashTable{{0, 4} => Tally{{0, 0, 0, 0, 0, 2} => 1}}
                               {1, 3} => Tally{{1, 0, 0, 0, 1, 2} => 1}
                               {2, 2} => Tally{{0, 1, 0, 1, 0, 2} => 1}
                               {3, 1} => Tally{{0, 0, 1, 0, 0, 2} => 1}
                4 => HashTable{{1, 4} => Tally{{1, 0, 0, 0, 0, 3} => 1}}
                               {2, 3} => Tally{{0, 1, 0, 0, 1, 3} => 1}
                               {3, 2} => Tally{{0, 0, 0, 1, 0, 3} => 1}
                5 => HashTable{{2, 4} => Tally{{0, 1, 0, 0, 0, 4} => 1}}
                               {3, 3} => Tally{{0, 0, 0, 0, 1, 4} => 1}
                6 => HashTable{{3, 4} => Tally{{0, 0, 0, 0, 0, 5} => 1}}

o12 : HashTable

We show what part of the resolution looks like in terms of Schur functors: $$R \leftarrow (\wedge^2 F \otimes R(0,-2)) \oplus (E \otimes F \otimes R(-1,-1)) \oplus (\wedge^2 E \otimes R(-2,0)) \leftarrow (\wedge^3 F \otimes H \otimes R(0,-3)) \oplus (E \otimes \wedge^2 F \otimes H \otimes R(-1,-2)) \oplus (\wedge^2 E \otimes F \otimes H \otimes R(-2,-1)) \oplus (H \otimes R(-3,0)) \leftarrow \ldots$$

Finally we decompose some graded components in the quotient ring $R/I$. Unlike with $\ZZ$-gradings, when working in the multigraded setting it is not possible to decompose a range of degrees but only one multidegree at a time.

i13 : Q=R/I

o13 = Q

o13 : QuotientRing
i14 : highestWeightsDecomposition(Q,{2,0})

o14 = Tally{{2, 0, 0, 0, 0, 2} => 1}

o14 : Tally
i15 : highestWeightsDecomposition(Q,{1,1})

o15 = Tally{{1, 0, 1, 0, 0, 2} => 1}

o15 : Tally
i16 : highestWeightsDecomposition(Q,{0,2})

o16 = Tally{{0, 0, 2, 0, 0, 2} => 1}

o16 : Tally

We have $Q_{(2,0)} = S_2 E \otimes S_2 H$, $Q_{(1,1)} = E \otimes F \otimes S_2 H$ and $Q_{(0,2)} = S_2 F \otimes S_2 H$.