next | previous | forward | backward | up | top | index | toc | Macaulay2 website
Book3264Examples > Intersection Theory Section 4.3

Intersection Theory Section 4.3 -- Schubert calculus in general

Subsection 4.3.1

We build arbitrary Schubert cycles using the command placeholderSchubertCycle. For example, on ${\mathbb G}(2,4)$, we can build the cycle $\sigma_{2,1,1}$ as follows:

i1 : G24 = flagBundle({3,2})

o1 = G24

o1 : a flag bundle with subquotient ranks {3, 2}
i2 : sigma_(2,1,1) = placeholderSchubertCycle({2,1,1},G24)

      2          2
o2 = H   H    - H
      2,1 2,2    2,2

                                            QQ[][H   ..H   , H   ..H   ]
                                                  1,1   1,3   2,1   2,2
o2 : ---------------------------------------------------------------------------------------------------------
     (- H    - H   , - H    - H   H    - H   , - H    - H   H    - H   H   , - H   H    - H   H   , -H   H   )
         1,1    2,1     1,2    1,1 2,1    2,2     1,3    1,2 2,1    1,1 2,2     1,3 2,1    1,2 2,2    1,3 2,2

Subsection 4.3.2

Exercise 4.34

How many lines meet 6 general 2-planes in ${\mathbb P}^4$?

The cycle of lines meeting a 2-plane in the Grassmannian ${\mathbb G}(1,4)$ is the Schubert cycle $\sigma_1$, so the number of lines meeting 6 general 2-planes is the degree of $(\sigma_1)^6$:

i3 : G14 = flagBundle({2,3})

o3 = G14

o3 : a flag bundle with subquotient ranks {2..3}
i4 : sigma_1 = placeholderSchubertCycle({1,0},G14)

o4 = H
      2,1

                                            QQ[][H   ..H   , H   ..H   ]
                                                  1,1   1,2   2,1   2,3
o4 : ---------------------------------------------------------------------------------------------------------
     (- H    - H   , - H    - H   H    - H   , - H   H    - H   H    - H   , - H   H    - H   H   , -H   H   )
         1,1    2,1     1,2    1,1 2,1    2,2     1,2 2,1    1,1 2,2    2,3     1,2 2,2    1,1 2,3    1,2 2,3
i5 : integral (sigma_1)^6

o5 = 5

Note that this is the degree of ${\mathbb G}(1,4)$ in the Plucker embedding, since $\sigma_1$ is the hyperplane class.

Exercise 4.36 (a)

How many lines meet four general $k$-planes in ${\mathbb P}^{2k+1}$?

The cycles of lines meeting a $k$-plane in ${\mathbb G}(1,2k+1)$ is the Schubert cycle $\sigma_k$. We can build a function that calculates this value for any $k$, but we cannot use $k$ as a base parameter, since we need to build a different Grassmannian and Schubert cycle for each $k$.

i6 : numOfLines = k -> (
          G := flagBundle({2,2*k});
          sigma := placeholderSchubertCycle({k,0}, G);
          integral sigma^4)

o6 = numOfLines

o6 : FunctionClosure

Now we can calculate to our hearts' content:

i7 : for k from 1 to 5 do (
          << numOfLines(k) << " lines meet four " << k << "-planes in P" << 2*k+1 << "\n")
2 lines meet four 1-planes in P3
3 lines meet four 2-planes in P5
4 lines meet four 3-planes in P7
5 lines meet four 4-planes in P9
6 lines meet four 5-planes in P11

Calculations slow down pretty quickly as $k$ gets large (the bottleneck is building the Chow ring), but we suspect the reader will have guessed the correct formula from the above data.

Linear Spaces on Quadrics

Exercise 4.43

A 2-plane in ${\mathbb P}^6$ is the same as a 3-plane in a 7-dimensional space. According to Proposition 4.42, the cycle of 3-planes contained in the zero-locus of a nondegenerate quadratic form on a 7-dimensional space is $2^3\sigma_{3,2,1}$ in $G(3,7)$. Hence we calculate:

i8 : G37 = flagBundle({3,4})

o8 = G37

o8 : a flag bundle with subquotient ranks {3..4}
i9 : A37 = intersectionRing G37

o9 = A37

o9 : QuotientRing
i10 : sigma = 8*placeholderSchubertCycle({3,2,1},G37)

                        2       2
o10 = 8H   H   H    - 8H    - 8H   H
        2,1 2,2 2,3     2,3     2,1 2,4

o10 : A37
i11 : integral sigma^2

o11 = 64

More generally, we can ask: given 2 general quadrics in ${\mathbb P}^{2k+2}$, how many $k$-planes are contained in their intersection? We calculate:

i12 : numOfPlanes = k -> (
           G:= flagBundle({k+1,k+2});
           schubertlist := apply(k+1,i-> k+1-i); --the list {k+1,k,...,1}
           sigma := (2^(k+1))*placeholderSchubertCycle(schubertlist, G);
           integral sigma^2)

o12 = numOfPlanes

o12 : FunctionClosure
i13 : numOfPlanes(2) --This was Exercise 4.43

o13 = 64
i14 : for k from 2 to 4 do (
           << numOfPlanes(k) << " " << k << "-planes in two quadrics in P" << 2*k+2 <<"\n")
64 2-planes in two quadrics in P6
256 3-planes in two quadrics in P8
1024 4-planes in two quadrics in P10

Exercise 4.44:

Compute $\sigma_{2,1}^2$ in the Chow ring of $G(3,6)$.

This is easy with the function placeholderToSchubertBasis, which we already saw in Intersection Theory Section 4.2:

i15 : G36 = flagBundle({3,3})

o15 = G36

o15 : a flag bundle with subquotient ranks {2:3}
i16 : c = placeholderSchubertCycle({2,1,0},G36)

o16 = H   H    - H
       2,1 2,2    2,3

                                                                       QQ[][H   ..H   ]
                                                                             1,1   2,3
o16 : --------------------------------------------------------------------------------------------------------------------------------------------------
      (- H    - H   , - H    - H   H    - H   , - H    - H   H    - H   H    - H   , - H   H    - H   H    - H   H   , - H   H    - H   H   , -H   H   )
          1,1    2,1     1,2    1,1 2,1    2,2     1,3    1,2 2,1    1,1 2,2    2,3     1,3 2,1    1,2 2,2    1,1 2,3     1,3 2,2    1,2 2,3    1,3 2,3
i17 : placeholderToSchubertBasis(c^2,G36)

o17 = s          + 2s          + s
       {2, 2, 2}     {3, 2, 1}    {3, 3, 0}

o17 : QQ[][s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         , s         ]
            {0, 0, 0}   {1, 0, 0}   {1, 1, 0}   {1, 1, 1}   {2, 0, 0}   {2, 1, 0}   {2, 1, 1}   {2, 2, 0}   {2, 2, 1}   {2, 2, 2}   {3, 0, 0}   {3, 1, 0}   {3, 1, 1}   {3, 2, 0}   {3, 2, 1}   {3, 2, 2}   {3, 3, 0}   {3, 3, 1}   {3, 3, 2}   {3, 3, 3}

We see that $\sigma_{3,2,1}$ occurs with coefficient $2$ in $\sigma_{2,1}^2$.