next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: kleinschmidt(ZZ,List)

kleinschmidt(ZZ,List) -- make a smooth normal toric variety with Picard rank two

Synopsis

Description

Peter Kleinschmidt constructs (up to isomorphism) all smooth normal toric varieties with dimension d and d+2 rays; see P. Kleinschmidt, A classification of toric varieties with few generators Aequationes Mathematicae, 35 (1998) 254-266.

When d=2, we obtain a variety isomorphic to a Hirzebruch surface. By permuting the indexing of the rays and taking an automorphism of the lattice, we produce an explicit isomorphism.

i1 : X = kleinschmidt (2,{3});
i2 : rays X

o2 = {{-1, 0}, {1, 0}, {0, 1}, {3, -1}}

o2 : List
i3 : max X

o3 = {{0, 2}, {0, 3}, {1, 2}, {1, 3}}

o3 : List
i4 : FF3 = hirzebruchSurface 3;
i5 : rays FF3

o5 = {{1, 0}, {0, 1}, {-1, 3}, {0, -1}}

o5 : List
i6 : max FF3

o6 = {{0, 1}, {0, 3}, {1, 2}, {2, 3}}

o6 : List
i7 : permutingRays = matrix {{0,0,0,1},{0,1,0,0},{1,0,0,0},{0,0,1,0}}

o7 = | 0 0 0 1 |
     | 0 1 0 0 |
     | 1 0 0 0 |
     | 0 0 1 0 |

              4        4
o7 : Matrix ZZ  <--- ZZ
i8 : latticeAutomorphism = matrix {{0,1},{1,0}}

o8 = | 0 1 |
     | 1 0 |

              2        2
o8 : Matrix ZZ  <--- ZZ
i9 : assert (latticeAutomorphism * (matrix transpose rays X) * permutingRays == matrix transpose rays FF3)

The normal toric variety associated to the pair (d,a) is Fano if and only if i=0r-1 ai < d-r+1.

i10 : X1 = kleinschmidt (3, {0,1});
i11 : isFano X1

o11 = true
i12 : X2 = kleinschmidt (4, {0,0});
i13 : isFano X2

o13 = true
i14 : ring X2

o14 = QQ[x , x , x , x , x , x ]
          0   1   2   3   4   5

o14 : PolynomialRing
i15 : X3 = kleinschmidt (9, {1,2,3}, CoefficientRing => ZZ/32003, Variable => y);
i16 : isFano X3

o16 = true
i17 : ring X3

        ZZ
o17 = -----[y , y , y , y , y , y , y , y , y , y , y  ]
      32003  0   1   2   3   4   5   6   7   8   9   10

o17 : PolynomialRing

The map from the torus-invariant Weil divisors to the class group is chosen so that the positive orthant corresponds to the cone of nef line bundles.

i18 : nefGenerators X

o18 = | 1 0 |
      | 0 1 |

               2        2
o18 : Matrix ZZ  <--- ZZ
i19 : nefGenerators X1

o19 = | 1 0 |
      | 0 1 |

               2        2
o19 : Matrix ZZ  <--- ZZ
i20 : nefGenerators X2

o20 = | 1 0 |
      | 0 1 |

               2        2
o20 : Matrix ZZ  <--- ZZ
i21 : nefGenerators X3

o21 = | 1 0 |
      | 0 1 |

               2        2
o21 : Matrix ZZ  <--- ZZ

See also