next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
NormalToricVarieties :: hirzebruchSurface(ZZ)

hirzebruchSurface(ZZ) -- make a Hirzebruch surface

Synopsis

Description

The a-th Hirzebruch surface is a smooth projective normal toric variety. It can be defined as the 1-bundle over X = ℙ1 associated to the sheaf OX(0) ⊕OX(a). It is also the quotient of affine 4-space by a rank two torus.

i1 : FF3 = hirzebruchSurface 3;
i2 : rays FF3

o2 = {{1, 0}, {0, 1}, {-1, 3}, {0, -1}}

o2 : List
i3 : max FF3

o3 = {{0, 1}, {0, 3}, {1, 2}, {2, 3}}

o3 : List
i4 : dim FF3

o4 = 2
i5 : ring FF3

o5 = QQ[x , x , x , x ]
         0   1   2   3

o5 : PolynomialRing
i6 : degrees ring FF3

o6 = {{1, 0}, {-3, 1}, {1, 0}, {0, 1}}

o6 : List
i7 : ideal FF3

o7 = ideal (x x , x x , x x , x x )
             2 3   1 2   0 3   0 1

o7 : Ideal of QQ[x , x , x , x ]
                  0   1   2   3
i8 : assert (isProjective FF3 and isSmooth FF3)

When a = 0, we obtain 1 ×ℙ1.

i9 : FF0 = hirzebruchSurface (0, CoefficientRing => ZZ/32003, Variable => y);
i10 : rays FF0

o10 = {{1, 0}, {0, 1}, {-1, 0}, {0, -1}}

o10 : List
i11 : max FF0

o11 = {{0, 1}, {0, 3}, {1, 2}, {2, 3}}

o11 : List
i12 : ring FF0

        ZZ
o12 = -----[y , y , y , y ]
      32003  0   1   2   3

o12 : PolynomialRing
i13 : degrees ring FF0

o13 = {{1, 0}, {0, 1}, {1, 0}, {0, 1}}

o13 : List
i14 : I = ideal FF0

o14 = ideal (y y , y y , y y , y y )
              2 3   1 2   0 3   0 1

                 ZZ
o14 : Ideal of -----[y , y , y , y ]
               32003  0   1   2   3
i15 : decompose I

o15 = {ideal (y , y ), ideal (y , y )}
               2   0           3   1

o15 : List
i16 : assert (isProjective FF3 and isSmooth FF3)

The map from the torus-invariant Weil divisors to the class group is chosen so that the positive orthant corresponds to the cone of nef line bundles.

i17 : nefGenerators FF3

o17 = | 1 0 |
      | 0 1 |

               2        2
o17 : Matrix ZZ  <--- ZZ
i18 : nefGenerators FF0

o18 = | 1 0 |
      | 0 1 |

               2        2
o18 : Matrix ZZ  <--- ZZ

See also