next | previous | forward | backward | up | top | index | toc | Macaulay2 web site
Macaulay2Doc :: Function _ Thing

Function _ Thing -- attach the first argument to a function of two or more arguments

Synopsis

Description

This abbreviation allows us to save a bit of typing, and in some cases, agrees with standard mathematical notation.

We use the identity function in the following examples, so we can exactly what sequence of arguments is constructed.

i1 : identity_a x

o1 = (a, x)

o1 : Sequence
i2 : identity_a (x,y)

o2 = (a, x, y)

o2 : Sequence
i3 : identity_(a,b) x

o3 = (a, b, x)

o3 : Sequence
i4 : identity_(a,b) (x,y)

o4 = (a, b, x, y)

o4 : Sequence

In the following examples, we show more typical uses of this notation.

i5 : R = ZZ[a .. i];
i6 : f = genericMatrix(R,a,3,3)

o6 = | a d g |
     | b e h |
     | c f i |

             3       3
o6 : Matrix R  <--- R
i7 : exteriorPower(2,f)

o7 = | -bd+ae -bg+ah -eg+dh |
     | -cd+af -cg+ai -fg+di |
     | -ce+bf -ch+bi -fh+ei |

             3       3
o7 : Matrix R  <--- R
i8 : exteriorPower_2 f

o8 = | -bd+ae -bg+ah -eg+dh |
     | -cd+af -cg+ai -fg+di |
     | -ce+bf -ch+bi -fh+ei |

             3       3
o8 : Matrix R  <--- R
i9 : p = prepend_7

o9 = p

o9 : FunctionClosure
i10 : p {8,9,10}

o10 = {7, 8, 9, 10}

o10 : List